blob: 4586dc5ad876d3c16f88eeb0b574b561a80de4a1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: SneakySnake <radiantstatue@gmail.com>
# Submit issues/pull requests at https://github.com/crumblingstatue/aur-mingw-w64-sdl2
pkgname=mingw-w64-sdl2
pkgver=2.0.8
pkgrel=1
pkgdesc='A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2) (mingw-w64)'
license=('MIT')
url='http://libsdl.org'
arch=('any')
_archs=('i686-w64-mingw32' 'x86_64-w64-mingw32')
depends=()
makedepends=('mingw-w64-configure')
source=("${url}/release/SDL2-${pkgver}.tar.gz")
sha256sums=('edc77c57308661d576e843344d8638e025a7818bff73f8fbfab09c3c5fd092ec')
options=(staticlibs !strip !buildflags)
build() {
cd "${srcdir}/SDL2-${pkgver}"
for _arch in ${_archs[@]}; do
unset LDFLAGS
mkdir build-${_arch} -p
pushd build-${_arch}
${_arch}-configure --enable-render-d3d=no
make
popd
done
}
package() {
cd "${srcdir}/SDL2-${pkgver}"
install -d "${pkgdir}"/usr/bin
for _arch in ${_archs[@]}; do
pushd build-${_arch}
make DESTDIR="${pkgdir}" install
find "${pkgdir}/usr/${_arch}/bin" -name "*.dll" -exec ${_arch}-strip --strip-unneeded {} \;
find "${pkgdir}/usr/${_arch}/lib" -name "*.a" -exec ${_arch}-strip -g {} \;
rm "${pkgdir}/usr/${_arch}/share" -r
ln -s "/usr/${_arch}/bin/sdl2-config" \
"${pkgdir}/usr/bin/${_arch}-sdl2-config"
popd
done
}
|