blob: d4353dae6ae3eb602cfd920fb3e21886bb13e0fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: julienCXX <archlinux@chmodplusx.eu>
# Contributor: Moritz Maxeiner <moritz@ucworks.org>
pkgname=mingw-w64-seafile-shared
pkgver=4.3.1
pkgrel=1
pkgdesc="Shared components of seafile: seafile-daemon, libseafile, libseafile python bindings (mingw-w64)."
arch=(any)
url="https://github.com/haiwen/seafile/"
license=('GPL')
makedepends=('mingw-w64-configure' 'vala' 'intltool' 'python2>=2.6')
depends=('mingw-w64-crt' 'mingw-w64-ccnet>=3.0' 'mingw-w64-curl')
options=('!strip' '!buildflags' 'staticlibs')
source=("seafile-${pkgver}.tar.gz::https://github.com/haiwen/seafile/archive/v${pkgver}.tar.gz"
"seafile-pull-1265.patch::https://patch-diff.githubusercontent.com/raw/haiwen/seafile/pull/1265.patch")
sha256sums=('56791c096dfde0283d8280102139f7c7df88789a4152a1a037c8e573087ac9ce'
'50ef89aa3d4382af7ba45c9c95530ce8b3a9c355dd1c425c35a26651c62692bb')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd "$srcdir/seafile-${pkgver}"
# Fix for reference to $pkgdir in package
sed -i 's/(DESTDIR)//g' lib/libseafile.pc.in
# Fix for 64-bit compilation
patch -p1 -i "$srcdir"/seafile-pull-1265.patch
# Case fixes on includes and configure script
sed -i 's/<Rpc.h>/<rpc.h>/g' lib/utils.c
sed -i 's/<AccCtrl.h>/<accctrl.h>/g' daemon/set-perm.c
sed -i 's/<AclApi.h>/<aclapi.h>/g' daemon/set-perm.c
sed -i 's/-lRpcrt4/-lrpcrt4/g' configure.ac
}
build()
{
cd "$srcdir/seafile-${pkgver}"
# Required for the build process to find searpc-codegen.py
export PATH=/usr/i686-w64-mingw32/bin/:"$PATH"
./autogen.sh
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
cp -r ../lib lib
${_arch}-configure PYTHON=python2
make
popd
done
}
package()
{
for _arch in ${_architectures}; do
cd "${srcdir}/seafile-${pkgver}/build-${_arch}"
make DESTDIR="$pkgdir" install
mkdir -p "$pkgdir"/usr/"$_arch"/lib/python2.7/site-packages/
mv "$pkgdir"/Lib/site-packages/* "$pkgdir"/usr/"$_arch"/lib/python2.7/site-packages/
rm -rf "$pkgdir"/Lib
rm -rf "$pkgdir"/usr/"$_arch"/share
${_arch}-strip --strip-unneeded "${pkgdir}"/usr/${_arch}/bin/*.{dll,exe}
${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
|