blob: 5a9f938956fff9519d3ea5087bedad84999a85ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Asterios Dimitriou <asterios@pci.gr>
_pkgname=sqlcipher
pkgname=mingw-w64-sqlcipher
pkgver=4.4.2
pkgrel=1
pkgdesc="SQLite extension that provides transparent 256-bit AES encryption of database files (mingw-w64)"
arch=('any')
url="https://www.zetetic.net/sqlcipher/"
license=('BSD')
makedepends=('mingw-w64-configure' 'tcl')
depends=('mingw-w64-crt' 'mingw-w64-openssl')
options=(!buildflags !strip staticlibs !makeflags)
source=("${_pkgname}-${pkgver}.zip::https://github.com/${_pkgname}/${_pkgname}/archive/v${pkgver}.zip"
"01-fix_extensions.patch")
sha256sums=('6bb5c154ef979ddd28f4668846f394ae2ccbf6cece09a9148b73fadf8adc7b55'
'614f3b66e3ded3e4f140129cb8a16aae5f0df3808596ce5f1f032c79ae665c48')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare(){
cd "${srcdir}/${_pkgname}-${pkgver}/"
patch -p1 -i "${srcdir}"/01-fix_extensions.patch
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}/"
for _arch in ${_architectures}; do
mkdir -p build-${_arch} && pushd build-${_arch}
CFLAGS="-DSQLITE_HAS_CODEC -DSQLITE_ENABLE_COLUMN_METADATA" \
LDFLAGS="-lcrypto" \
config_TARGET_EXEEXT=.exe \
${_arch}-configure \
--enable-tempstore \
--disable-tcl \
--enable-session \
--enable-fts3 \
--enable-fts5 \
--enable-json1 \
--enable-rtree \
..
make
popd
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}/${_pkgname}-${pkgver}/build-${_arch}"
make DESTDIR="${pkgdir}" install
${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
done
}
|