PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

pkgname=mingw-w64-tools
pkgver=9.0.0
pkgrel=1
pkgdesc="MinGW-w64 utilities"
arch=(i686 x86_64)
url="http://mingw-w64.sourceforge.net"
license=("GPL3" "LGPL2")
groups=(mingw-w64)
options=(!libtool !emptydirs)
validpgpkeys=('CAF5641F74F7DFBA88AE205693BDB53CD4EBC740')
source=(https://sourceforge.net/projects/mingw-w64/files/mingw-w64/mingw-w64-release/mingw-w64-v${pkgver}.tar.bz2{,.sig})
sha256sums=('1929b94b402f5ff4d7d37a9fe88daa9cc55515a6134805c104d1794ae22a4181'
            'SKIP')

_architectures="i686-w64-mingw32 x86_64-w64-mingw32"

build() {
  cd "${srcdir}"
  for tool in gendef genidl genlib genpeimg; do
    mkdir -p "${srcdir}"/${tool}-build && cd "${srcdir}"/${tool}-build
    "${srcdir}"/mingw-w64-v${pkgver}/mingw-w64-tools/${tool}/configure --prefix=/usr
    make
  done
  for _arch in ${_architectures}; do
    mkdir -p "${srcdir}"/widl-${_arch}-build && cd "${srcdir}"/widl-${_arch}-build
    "${srcdir}"/mingw-w64-v${pkgver}/mingw-w64-tools/widl/configure --prefix=/usr --target=${_arch} \
      --program-prefix="${_arch}-"
    make
  done
}

package() {
  for tool in gendef genidl genlib genpeimg; do
    cd "${srcdir}/${tool}-build"
    make DESTDIR="${pkgdir}" install
  done
  for _arch in ${_architectures}; do
    cd "${srcdir}/widl-${_arch}-build"
    make DESTDIR="${pkgdir}" install
  done
  install -d "${pkgdir}"/usr/share/licenses/${pkgname}
  for tool in gendef genidl genlib genpeimg; do
    install -m644 "${srcdir}/mingw-w64-v${pkgver}/mingw-w64-tools/${tool}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING.${tool}"
  done
}