blob: 6e1c151f6704a64147f4acc7e0eb247db41330af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Karl-Felix Glatzer <karl.glatzer@gmx.de>
pkgname=mingw-w64-x265
pkgver=2.1
pkgrel=2
pkgdesc='Open Source H265/HEVC video encoder (mingw-w64)'
arch=('any')
url='https://bitbucket.org/multicoreware/x265'
license=('GPL')
depends=('mingw-w64-crt')
options=(!strip !buildflags staticlibs)
makedepends=('mingw-w64-cmake' 'yasm')
source=("https://bitbucket.org/multicoreware/x265/downloads/x265_${pkgver}.tar.gz"
mingw.patch)
sha256sums=('88fcb9af4ba52c0757ac9c0d8cd5ec79951a22905ae886897e06954353d6a643'
'90b8e81cd5228d2b147fbd6c000921d5b7593819e378d0e73c11c8de390796bc')
_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
prepare() {
cd x265_${pkgver}
patch -Np1 -i "${srcdir}/mingw.patch"
}
build() {
for _arch in ${_architectures}; do
mkdir -p "${srcdir}"/build-${_arch} && cd "${srcdir}"/build-${_arch}
unset LDFLAGS CPPFLAGS
${_arch}-cmake \
-DLIB_INSTALL_DIR="lib" \
-DENABLE_SHARED='TRUE' \
-DENABLE_CLI='FALSE' \
"${srcdir}"/x265_${pkgver}/source
make
done
}
package() {
for _arch in ${_architectures}; do
cd "${srcdir}"/build-${_arch}
make DESTDIR="$pkgdir" install
${_arch}-strip -x -g "${pkgdir}"/usr/${_arch}/bin/*.dll
${_arch}-strip -g "${pkgdir}"/usr/${_arch}/lib/*.a
done
}
# vim: ts=2 sw=2 et:
|