blob: 82df5ca190215d5445efca1f85394dc3fa7d304d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Wouter Wijsman <wwijsman@live.nl>
pkgname=minigalaxy
_app_id=io.github.sharkwouter.Minigalaxy
pkgver=1.2.6
pkgrel=1
pkgdesc="A simple GOG client for Linux"
arch=('any')
url="https://sharkwouter.github.io/minigalaxy"
license=('GPL-3.0-or-later AND CC-BY-3.0')
depends=(
'gtk3'
'libnotify'
'python-gobject'
'python-requests'
'unrar'
'unzip'
'webkit2gtk'
'xdg-utils'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=('appstream')
optdepends=(
'dosbox: Use the system DOSBox installation'
'innoextract: Extract Windows installers'
'scummvm: Use the system ScummVM installation'
'wine: Install Windows games'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/sharkwouter/minigalaxy/archive/$pkgver.tar.gz")
sha256sums=('840131049e133fca386ca2a1a9e5d7f5d8d86ba5fc03c2398dd518c06aa6afd4')
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "$pkgname-$pkgver"
appstreamcli validate --no-net "data/${_app_id}.metainfo.xml" || :
desktop-file-validate "data/${_app_id}.desktop"
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 THIRD-PARTY-LICENSES.md -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|