PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Daniel Bermond <dbermond@archlinux.org>

_target=mips64-linux-gnu
pkgname="${_target}-gdb"
pkgver=15.1
pkgrel=1
pkgdesc='The GNU Debugger for the MIPS64 target (for the toolchain with GNU C library and multilib ABI)'
arch=('x86_64')
url='https://www.gnu.org/software/gdb/'
license=('GPL-3.0-or-later')
depends=('expat' 'gdb-common' 'guile' 'libelf' 'ncurses' 'mpfr' 'python' 'xz')
options=('!emptydirs')
source=("https://ftp.gnu.org/gnu/gdb/gdb-${pkgver}.tar.xz"{,.sig})
sha256sums=('38254eacd4572134bca9c5a5aa4d4ca564cbbd30c369d881f733fb6b903354f2'
            'SKIP')
validpgpkeys=('F40ADB902B24264AA42E50BF92EDB04BFF325CF3') # Joel Brobecker

prepare() {
    mkdir -p build
}

build() {
    cd build
    "${srcdir}/gdb-${pkgver}/configure" \
        --target="$_target" \
        --prefix='/usr' \
        --disable-nls \
        --disable-source-highlight \
        --enable-tui \
        --with-system-readline \
        --with-python='/usr/bin/python' \
        --with-system-gdbinit='/etc/gdb/gdbinit' \
        --enable-languages='c,c++,fortran' \
        --enable-multilib \
        --enable-interwork \
        --disable-werror
    make
}

package() {
    make -C build DESTDIR="$pkgdir" install
    rm -r "${pkgdir}/usr/include/gdb"
    rm -r "${pkgdir}/usr/share/gdb"
    rm -r "${pkgdir}/usr/share/info"
    rm -r "${pkgdir}/usr/share/man/man5"
    rm -r "${pkgdir}/usr/share/man/man1/${_target}-gdbserver.1"
}