PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Ivan Semkin (ivan at semkin dot ru)
# Contributor: kikadf <kikadf.01@gmail.com>

pkgname=mir-git
pkgver=2.29.0.dev.r135.gf55b60e
pkgrel=2
pkgdesc="Canonical's display server"
url="https://github.com/canonical/mir"
arch=(x86_64 i686 armv7h aarch64)
license=('GPL-2.0-or-later OR GPL-3.0-or-later')
depends=(
    boost-libs
    egl-wayland
    freetype2
    glib2
    glibc
    glibmm
    gtest
    hicolor-icon-theme
    libdisplay-info
    libdrm
    libepoxy
    libgcc
    libglvnd
    libinput
    libstdc++
    libx11
    libxcb
    libxcursor
    libxkbcommon
    libxkbcommon-x11
    libxml++2.6
    lttng-ust
    mesa
    pixman
    sh
    systemd-libs
    util-linux-libs
    wayland
    yaml-cpp
    )
makedepends=(
    boost
    cargo
    cmake
    doxygen
    git
    glib2-devel
    glm
    glmark2
    graphviz
    python-dbus
    python-dbusmock
    python-pillow
    umockdev
    wlcs
    xorg-xwayland
    )
optdepends=('qterminal: required for miral demos'
            'ttf-ubuntu-font-family: required for miral demos'
            'qt5-wayland: required for miral demos'
            'xcursor-dmz: opt requirement for miral demos')
conflicts=(mir)
provides=(mir)
options=(!lto)
source=("git+https://github.com/canonical/mir.git")
sha256sums=('SKIP')

pkgver() {
  cd "mir"
  git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  local _flags=(
    -DMIR_FATAL_COMPILE_WARNINGS=OFF
    -DCMAKE_INSTALL_LIBEXECDIR=/usr/lib/mir/
    -DMIR_BUILD_INTERPROCESS_TESTS=OFF
    -DMIR_USE_PRECOMPILED_HEADERS=OFF
    -DMIR_FATAL_COMPILE_WARNINGS=OFF
    -DMIR_ENABLE_WLCS_TESTS=OFF
    -DMIR_RUN_WLCS_TESTS=OFF
    -DMIR_USE_LD=ld
  )

  cmake -B build -S "mir" -Wno-dev \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    "${_flags[@]}"

  cmake --build build
}

#check() {
  #ctest --test-dir build --output-on-failure
  #error: XDG_RUNTIME_DIR is invalid or not set in the environment
  #Mir fatal error: Unable to bind Wayland socket
#}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}