blob: 5ad5cefaeb7052878dda2904ea32765d8823a222 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Dmytro Meleshko <dmytro.meleshko@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Scott Horowitz <stonecrest@gmail.com>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgname=mirage
pkgver=1.0_pre2
pkgrel=3
pkgdesc="A simple GTK+ Image Viewer"
url="https://sourceforge.net/projects/mirageiv.berlios/"
license=('GPL')
depends=('pygtk' 'libexif')
optdepends=('gnome-python: toolbar setting support in GNOME')
arch=('x86_64')
source=(http://downloads.sourceforge.net/project/mirageiv.berlios/${pkgname}-${pkgver}.tar.bz2
exif.patch
exif.c)
install=$pkgname.install
sha256sums=('6b5b0011f41daec3653c464e47fd225e52b741fcad8870960e0a94662a2fdda7'
'a669be216365c84bc1f4dc3d08ee97ed0b0eee083c0293004a3f2772f9e177bd'
'6c680c8dd8a323ceeee7492e4c7db0280fd7fe2df1c4ed0b13bc9c4f3d6d8917')
prepare() {
cd "${pkgname}-${pkgver}"
patch --forward --strip=1 --input="${srcdir}/exif.patch"
cp "${srcdir}/exif.c" .
}
build() {
cd "${pkgname}-${pkgver}"
python2 setup.py build
}
package() {
cd "${pkgname}-${pkgver}"
python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
}
|