blob: 094bd67d446843d3e85e9b5e2a05683ee17fe7ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer:
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: FFY00 <filipe.lains@gmail.com>
# Contributor: Simon 'ALSimon' Gilliot <simon@gilliot.fr>
# Contributor: Olivier Biesmans <olivier at biesmans dot fr>
# Contributor: Dobroslaw Kijowski
pkgname=mitmproxy-git
pkgver=10.1.5.r2.gd72b92bdf
pkgrel=1
pkgdesc='SSL-capable man-in-the-middle HTTP proxy'
arch=('any')
url="https://mitmproxy.org/"
license=('MIT')
depends=(
'python-aioquic'
'python-asgiref'
'python-blinker'
'python-brotli'
'python-certifi'
'python-cryptography'
'python-flask'
'python-h11'
'python-h2'
'python-hyperframe'
'python-kaitaistruct'
'python-ldap3'
'python-mitmproxy-rs'
'python-msgpack'
'python-passlib'
'python-protobuf'
'python-psutil'
'python-publicsuffix2'
'python-pylsqpack'
'python-pyopenssl'
'python-pyparsing'
'python-pyperclip'
'python-requests'
'python-ruamel-yaml'
'python-sortedcontainers'
'python-tornado'
'python-typing_extensions'
'python-urwid'
'python-werkzeug'
'python-wsproto'
'python-zstandard'
)
makedepends=('git' 'python-build' 'python-installer' 'python-wheel')
checkdepends=(
'python-asynctest'
'python-hypothesis'
'python-parver'
'python-pytest-asyncio'
'python-pytest-cov'
'python-pytest-runner'
'python-pytest-timeout'
'python-tox-current-env'
)
conflicts=('mitmproxy')
provides=('mitmproxy')
source=("git+https://github.com/mitmproxy/mitmproxy.git")
sha1sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --tags | sed 's/-/.r/;s/-/./g'
}
build() {
cd "${pkgname%-git}"
python -m build --wheel --no-isolation
}
check() {
cd "${pkgname%-git}"
local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
python -m installer --destdir=test_dir dist/*.whl
PATH="test_dir/usr/bin:$PATH" PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH" tox -e py --current-env
}
package() {
cd "${pkgname%-git}"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|