blob: 8b3a07f70b4bd3f110a8bfe3c90762e7d3cb7646 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Jeremy Audet <jerebear@protonmail.com>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: Arnaud Durand-Favreau <biginoz at FREE point FR>
#
# namcap warns that 'java-environment' is a dependency. This is untrue:
# java-runtime suffices. Also, java-runtime provides 'sh'.
#
pkgname=mkgmap
pkgver=r4244
pkgrel=1
pkgdesc='Create maps for Garmin GPS devices from OpenStreetMap (OSM) data.'
url='http://www.mkgmap.org.uk'
license=(GPL2)
arch=(any)
depends=('java-runtime=8')
conflicts=("${pkgname}-svn")
source=("${pkgname}" "http://www.mkgmap.org.uk/download/${pkgname}-${pkgver}.zip")
sha256sums=('135dfbca5146cea34ef48ed6908a817efdfbbcccbb8adfbbb6a100f58c2c7bb6'
'6e05bc0c78fad3c12f684a77b9fad8bcb737c913a3b53b09fc675eb1b3c39b6b')
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
# Install the executable, jarfile, dependencies and man page.
install -Dm755 "${srcdir}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 \
"${pkgname}.jar" \
"${pkgdir}/usr/share/java/${pkgname}/${pkgname}.jar"
cp -r lib/ "${pkgdir}/usr/share/java/${pkgname}/"
install -Dm644 "doc/${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
}
# vim:set ts=2 sw=2 et:
|