blob: 67eebc035f72a1b01290871379a9df75ea67e1f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Andy Weidenbaum <archbaum@gmail.com>
pkgname=mktxn
pkgver=0.0.5
pkgrel=1
pkgdesc="Double-entry accounting ledger packager"
arch=('any')
depends=('perl6'
'perl6-config-toml'
'perl6-file-presence'
'perl6-txn-parser'
'perl6-txn-remarshal')
checkdepends=('perl')
makedepends=('alacryd' 'git')
groups=('perl6')
url="https://github.com/atweiden/mktxn"
license=('UNLICENSE')
source=($pkgname-$pkgver::git+https://github.com/atweiden/mktxn
git+https://github.com/atweiden/txn-examples)
sha256sums=('SKIP' 'SKIP')
check() {
cd "$srcdir/$pkgname-$pkgver"
msg2 'Running tests...'
cp -dpr --no-preserve=ownership "$srcdir/txn-examples" t/data
PERL6LIB=lib prove -r -e perl6
}
package() {
cd "$srcdir/$pkgname-$pkgver"
msg2 'Installing license...'
install -Dm 644 UNLICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
msg2 'Installing documentation...'
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
msg2 'Installing...'
install -dm 755 "$pkgdir/usr/share/perl6/vendor"
export RAKUDO_LOG_PRECOMP=1
export PERL6LIB="inst#$pkgdir/usr/share/perl6/vendor"
alacryd install
msg2 'Removing redundant precomp file dependencies...'
_precomp=($(pacman -Qqg perl6 | pacman -Qql - | grep -E 'dist|precomp' || true))
for _pc in "${_precomp[@]}"; do
[[ -f "$pkgdir/$_pc" ]] && rm -f "$pkgdir/$_pc"
done
msg2 'Cleaning up pkgdir...'
rm -f "$pkgdir/usr/share/perl6/vendor/version"
find "$pkgdir" -type f -name "*.lock" -exec rm '{}' +
find "$pkgdir" -type f -print0 -exec \
sed -i -e "s,$pkgdir,,g" -e "s,$srcdir,,g" '{}' +
}
|