blob: 3e4bf79b9fe37124fa03660fdcc91b99e66da8cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: Funkin-Stoopid <>
pkgname=mkv-extractor-qt
pkgver=5.4.0
pkgrel=1
pkgdesc="Graphical mkv demultiplexer"
arch=('any')
url='http://forum.ubuntu-fr.org/viewtopic.php?id=1508741'
license=('GPL3')
depends=('python-pyqt5'
'mkvtoolnix-cli'
'hicolor-icon-theme'
)
optdepends=('ffmpeg: for DTS conversion'
'mkclean: MKV optimisation'
'mkvalidator: MKV check'
'qtesseract5: subtitle conversion'
)
makedepends=('qt5-tools'
'imagemagick'
)
conflicts=('mkv-extractor-gui')
replaces=('mkv-extractor-gui')
source=("https://launchpad.net/~hizo/+archive/ubuntu/mkv-extractor-gui/+files/mkv-extractor-qt5_${pkgver}.orig.tar.gz")
sha1sums=('8fb9fd4a9959ebb7f03a7725cd25a312d1c6671a')
prepare() {
cd mkv-extractor-qt5
sed -e 's|/usr/lib/x86_64-linux-gnu/qt5/bin/lrelease|/usr/bin/lrelease-qt5|g' \
-e 's|/usr/lib/i386-linux-gnu/qt5/bin/lrelease|/usr/bin/lrelease-qt5|g' \
-i build.sh
sed -e '/Encoding/d' \
-e 's|video/webm|video/webm;|g' \
-e 's|audio/x-matroska;audio/x-matroska|audio/x-matroska|g' \
-i mkv-extractor-qt5.desktop
export IFS=$'\n'
for i in $(find . -name '*.png' -type f); do
mogrify "${i}" &> /dev/null
done
export IFS=' '
}
build() {
cd mkv-extractor-qt5
make
}
package() {
install -d "${pkgdir}/usr/bin"
ln -s /usr/share/mkv-extractor-qt5/MKVExtractorQt5.py "${pkgdir}/usr/bin/mkv-extractor-qt5"
cd mkv-extractor-qt5
install -Dm755 MKVExtractorQt5.py "${pkgdir}/usr/share/mkv-extractor-qt5/MKVExtractorQt5.py"
install -Dm644 MKVRessources_rc.py "${pkgdir}/usr/share/mkv-extractor-qt5/MKVRessources_rc.py"
install -Dm644 ui_MKVExtractorQt5.py "${pkgdir}/usr/share/mkv-extractor-qt5/ui_MKVExtractorQt5.py"
install -Dm644 MKVExtractorQt5_cs_CZ.qm "${pkgdir}/usr/share/mkv-extractor-qt5/MKVExtractorQt5_cs_CZ.qm"
install -Dm644 MKVExtractorQt5_fr_FR.qm "${pkgdir}/usr/share/mkv-extractor-qt5/MKVExtractorQt5_fr_FR.qm"
install -Dm644 QFileDialogCustom/QFileDialogCustom.py "${pkgdir}/usr/share/mkv-extractor-qt5/QFileDialogCustom/QFileDialogCustom.py"
install -Dm644 QFileDialogCustom/QFileDialogCustom_fr_FR.qm "${pkgdir}/usr/share/mkv-extractor-qt5/QFileDialogCustom/QFileDialogCustom_fr_FR.qm"
install -Dm644 CodecListFile.py "${pkgdir}/usr/share/mkv-extractor-qt5/CodecListFile.py"
install -Dm644 mkv-extractor-qt5.desktop "${pkgdir}/usr/share/applications/mkv-extractor-qt5.desktop"
(cd icons; for i in $(find . -name *.png -type f); do install -Dm644 "${i}" "${pkgdir}/usr/share/icons/hicolor/${i}"; done)
}
|