blob: de053f844c06b5151eb0d155ba97e6068612baad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Jeremy Gust <jeremy AT plasticsoup DOT net>
# Contributor: Jameson Pugh <imntreal@gmail.com>
pkgname=moar
pkgver=1.17.1
pkgrel=1
pkgdesc="A pager designed to just do the right thing without any configuration."
arch=(x86_64)
url='https://github.com/walles/moar'
license=(BSD)
makedepends=(go)
optdepends=("highlight: source code syntax highlighter")
conflicts=(moar-bin)
source=("${pkgname}-${pkgver}.tar.gz"::"${url}/archive/v${pkgver}.tar.gz")
sha256sums=('56f381bfa113333a28aad6cdb40bf2c81b99338b6806d3ab1039b17df4a676f3')
build() {
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
cd "${srcdir}/${pkgname}-${pkgver}"
go build -ldflags="-s -w -X main.versionString=${pkgver}" -o "${pkgname}"
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -Dm755 moar "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 moar.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}
|