PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Can H. Tartanoglu <caniko@codeberg.org>
# Maintainer GPG key: 818D507F1E62139F8A17EAA64623DEA06FDACFE1
pkgname=modde-git
pkgver=0.4.0
pkgrel=1
pkgdesc='Cross-platform game mod manager'
arch=('x86_64')
url='https://codeberg.org/caniko/rs-modde'
license=('GPL-3.0-only')
depends=('dbus' 'gcc-libs' 'glibc' 'libxkbcommon' 'openssl' 'sqlite' 'vulkan-icd-loader' 'wayland')
makedepends=('cargo' 'cmake' 'git' 'pkgconf' 'rust')
provides=('modde')
conflicts=('modde' 'modde-bin')
source=('git+https://codeberg.org/caniko/rs-modde.git')
sha256sums=('SKIP')

pkgver() {
  cd rs-modde
  git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' || echo "$pkgver"
}

build() {
  cd rs-modde
  cargo build --release --locked --bin modde --bin modde-ui
}

package() {
  cd rs-modde
  install -Dm755 target/release/modde "$pkgdir/usr/bin/modde"
  install -Dm755 target/release/modde-ui "$pkgdir/usr/bin/modde-ui"
  install -Dm644 dist/modde-ui.desktop "$pkgdir/usr/share/applications/com.tartanoglu.modde.desktop"
  install -Dm644 dist/com.tartanoglu.modde.png "$pkgdir/usr/share/icons/hicolor/512x512/apps/com.tartanoglu.modde.png"
  install -Dm644 dist/assets/logo/logo.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/com.tartanoglu.modde.svg"
  install -Dm644 dist/com.tartanoglu.modde.metainfo.xml "$pkgdir/usr/share/metainfo/com.tartanoglu.modde.metainfo.xml"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  install -Dm644 CHANGELOG.md "$pkgdir/usr/share/doc/$pkgname/CHANGELOG.md"
}