blob: 0b099eb4dd16beb4c0322185407f6c3889558eb9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Antti <antti@antti.codes>
pkgname=modrinth-app
pkgver=0.6.3
pkgrel=1
pkgdesc='An unique, open source launcher that allows you to play your favorite mods, and keep them up to date, all in one neat little package.'
url='https://modrinth.com/app'
arch=('x86_64')
license=('GPL3')
makedepends=('rust' 'pnpm')
depends=(
# tauri deps
'openssl' 'dbus' 'freetype2' 'gtk3' 'libappindicator-gtk3' 'librsvg' 'libsoup' 'webkit2gtk'
# minecraft deps
'libgl' 'libpulse' 'libx11' 'libxcursor' 'libxext' 'libxxf86vm'
)
optdepends=(
'xorg-xrandr: for older minecraft versions'
)
conflicts=('modrinth-app-bin' 'modrinth-app-git')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/modrinth/theseus/archive/refs/tags/v${pkgver}.tar.gz"
"modrinth-app.desktop"
)
sha256sums=('b924ce16288f55b93ab26ec8511154d7e16fe38780065ea58082cb56bd045e8f'
'ad8f7ffea0435881acdd7ecb560443e281982727dc7c715885367e9466bc0a62')
options=('!lto')
prepare() {
cd "theseus-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
cd "theseus_gui"
pnpm install --frozen-lockfile --no-optional
}
build() {
cd "theseus-${pkgver}/theseus_gui/"
pnpm build
cd ..
export RUSTUP_TOOLCHAIN=stable
cargo build --frozen --release --all-features
}
check() {
cd "theseus-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
install -Dm755 "$srcdir"/theseus-"$pkgver"/target/release/theseus_gui "$pkgdir"/usr/bin/modrinth-app
install -Dm644 "$srcdir"/theseus-"$pkgver"/theseus_gui/src-tauri/icons/128x128.png "$pkgdir"/usr/share/icons/hicolor/128x128/apps/modrinth-app.png
install -Dm644 "$srcdir"/theseus-"$pkgver"/theseus_gui/src-tauri/icons/icon.png "$pkgdir"/usr/share/icons/hicolor/256x256@2/apps/modrinth-app.png
install -Dm644 modrinth-app.desktop "$pkgdir"/usr/share/applications/modrinth-app.desktop
}
|