blob: 55480073ca935231e819f4f17abfc8b23fc82eb3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
pkgname=mongodb-compass
pkgver=1.29.5
pkgrel=1
pkgdesc="The MongoDB GUI"
arch=('x86_64')
url="https://www.mongodb.com/products/compass"
license=('custom')
depends=('alsa-lib' 'gtk3' 'libsecret' 'libxss' 'libxtst' 'nss')
optdepends=('org.freedesktop.secrets')
source=("https://downloads.mongodb.com/compass/${pkgname}_${pkgver}_amd64.deb")
noextract=("${pkgname}_${pkgver}_amd64.deb")
b2sums=('2de6b19face327586259abcde9a2953b2cce66881ff03827d3823ccd44f6af0fb9b335cbb5bc75eb00272c53dfee7ff9820be7fdb79e88e21a87e62328cf2b1b')
package() {
bsdtar -O -xf "${pkgname}_${pkgver}"*.deb data.tar.xz | bsdtar -C "$pkgdir" -xJf -
# Permission fix
find "${pkgdir}" -type d -exec chmod 755 {} +
find "${pkgdir}" -type f -exec chmod 644 {} +
chmod +x "${pkgdir}"/usr/lib/mongodb-compass/"MongoDB Compass"
# Remove all unnecessary stuff
rm -rf "${pkgdir}/usr/share/lintian"
rm -rf "${pkgdir}/usr/share/doc"
# Install license
install -dm755 ${pkgdir}/usr/share/licenses/${pkgname}
ln -s /usr/share/${pkgname}/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}
}
|