blob: 7e0df0c7ed0baf5da758e7481e4129793981dcbf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
#Maintainer: Ali Molaei <ali dot molaei at protonmail dot com>
#Maintainer: Rafael Fontenelle <rafaelff at gnome dot org>
pkgname="mongodb50-bin"
pkgver="5.0.14"
_basever="5.0"
_basedist="focal"
pkgrel="1"
pkgdesc="A high-performance, open source, schema-free document-oriented database"
arch=("x86_64" "aarch64")
url="https://www.mongodb.com/"
license=("custom:SSPLv1" "Apache")
depends=(curl openssl-1.1)
makedepends=(chrpath)
optdepends=("mongodb-tools: The MongoDB tools provide import, export, and diagnostic capabilities."
"mongosh-bin: An interactive shell to connect with MongoDB with syntax highlighting, autocomplete, contextual help and error messages.")
provides=("mongodb=$pkgver")
conflicts=("mongodb" "mongodb-shell-bin")
backup=("etc/mongodb.conf")
_repo_url=https://repo.mongodb.org/apt/ubuntu/dists/${_basedist}/mongodb-org/${_basever}/multiverse
source=(
"mongodb.sysusers"
"mongodb.tmpfiles"
"LICENSE"
)
source_x86_64=(
mongodb-org-shell_${pkgver}_x86_64.deb::"${_repo_url}/binary-amd64/mongodb-org-shell_${pkgver}_amd64.deb"
mongodb-org-server_${pkgver}_x86_64.deb::"${_repo_url}/binary-amd64/mongodb-org-server_${pkgver}_amd64.deb"
mongodb-org-mongos_${pkgver}_x86_64.deb::"${_repo_url}/binary-amd64/mongodb-org-mongos_${pkgver}_amd64.deb"
)
source_aarch64=(
mongodb-org-shell_${pkgver}_aarch64.deb::"${_repo_url}/binary-arm64/mongodb-org-shell_${pkgver}_arm64.deb"
mongodb-org-server_${pkgver}_aarch64.deb::"${_repo_url}/binary-arm64/mongodb-org-server_${pkgver}_arm64.deb"
mongodb-org-mongos_${pkgver}_aarch64.deb::"${_repo_url}/binary-arm64/mongodb-org-mongos_${pkgver}_arm64.deb"
)
noextract=(
mongodb-org-shell_${pkgver}_${CARCH}.deb
mongodb-org-server_${pkgver}_${CARCH}.deb
mongodb-org-mongos_${pkgver}_${CARCH}.deb
)
sha256sums=('47b884569102f7c79017ee78ef2e98204a25aa834c0ee7d5d62c270ab05d4e2b'
'51ee1e1f71598aad919db79a195778e6cb6cfce48267565e88a401ebc64497ac'
'09d99ca61eb07873d5334077acba22c33e7f7d0a9fa08c92734e0ac8430d6e27')
sha256sums_x86_64=('219beafb7520fd44a56f909050a1d4b7a1d73265ebcc5888d9ee2ad3eb8545b7'
'79c58f4bd4a4d2a20cb28523c03baa0f54f2218797f3b3c6c68a682ec08cd5e3'
'9882490192f6e34f98641abd9516af2517b2b0735aee04a84e0c2d82d14543cb')
sha256sums_aarch64=('4be9b19b33d61fcd358be12caf27601b333ec8775f0a86ef0c7868641096146b'
'24872086812a820300c6ba6806d7d5aafd1137b9fad5de56257c26fcc94574c6'
'336b27ecd55d4bf8b4707bc724f5e06ba180ba13a296a2746c4b73d60299b68e')
prepare() {
mkdir -p output
bsdtar -O -xf mongodb-org-shell_${pkgver}_${CARCH}.deb data.tar.xz | bsdtar -C output -xJf - #mongo extracted
bsdtar -O -xf mongodb-org-server_${pkgver}_${CARCH}.deb data.tar.xz | bsdtar -C output -xJf - #server extracted
bsdtar -O -xf mongodb-org-mongos_${pkgver}_${CARCH}.deb data.tar.xz | bsdtar -C output -xJf - #mongos extracted
# Remove insecure RUNPATH '$ORIGIN/../lib' as reported by namcap
chrpath -d output/usr/bin/mongod
chrpath -d output/usr/bin/mongos
# Keep historical Arch dbPath
sed -i 's|dbPath: /var/lib/mongo$|dbPath: /var/lib/mongodb|' output/etc/mongod.conf
# Keep historical Arch conf file name
sed -i 's|/etc/mongod.conf|/etc/mongodb.conf|' output/lib/systemd/system/mongod.service
# Keep historical Arch user name (no need for separate daemon group name)
sed -i 's/User=mongod$/User=mongodb/' output/lib/systemd/system/mongod.service
sed -i 's/Group=mongod$/Group=mongodb/' output/lib/systemd/system/mongod.service
# Avoid legacy PID filepath
sed -i 's|/var/run/|/var/|' output/lib/systemd/system/mongod.service
# Remove sysconfig file, used by upstream's init.d script not used on Arch
sed -i '/^EnvironmentFile=/d' output/lib/systemd/system/mongod.service
# Make systemd wait as long as it takes for MongoDB to start
# If MongoDB needs a long time to start, prevent systemd from restarting it every 90 seconds
# See: https://jira.mongodb.org/browse/SERVER-38086
sed -i 's/\[Service]/[Service]\nTimeoutStartSec=infinity/' output/lib/systemd/system/mongod.service
}
package() {
install -Dm644 output/etc/mongod.conf "$pkgdir/etc/mongodb.conf"
install -Dm644 output/lib/systemd/system/mongod.service "$pkgdir/usr/lib/systemd/system/mongodb.service"
install -Dm755 output/usr/bin/* -t "$pkgdir/usr/bin"
install -Dm644 output/usr/share/man/man1/* -t "$pkgdir/usr/share/man/man1"
install -Dm644 mongodb.sysusers "$pkgdir/usr/lib/sysusers.d/mongodb.conf"
install -Dm644 mongodb.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/mongodb.conf"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|