blob: cc0ec1d812b6a90ef65eb49405f26b39b3702eef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
pkgname=mono-alpha
_pkgname=mono
pkgver=5.4.0.199
pkgrel=1
pkgdesc="Free implementation of the .NET platform including runtime and compiler. Alpha version."
arch=('i686' 'x86_64')
license=('GPL' 'LGPL2.1' 'MPL' 'BSD' 'custom=MITX11' 'custom=MSPL')
url="http://www.mono-project.com/"
depends=('zlib' 'libgdiplus' 'sh' 'python' 'ca-certificates')
makedepends=('cmake' 'mono')
provides=('monodoc' 'mono=${pkgver}')
conflicts=('monodoc' 'mono')
replaces=('mono' 'monodoc')
source=(https://download.mono-project.com/sources/mono/${_pkgname}-${pkgver}.tar.bz2
mono.binfmt.d)
md5sums=('7b2b9284922d311c75bda4c519ac7c1e'
'b9ef8a65fea497acf176cca16c1e2402')
install="mono.install"
build() {
cd "${srcdir}"/${_pkgname}-${pkgver}
# Build mono
./autogen.sh --prefix=/usr \
--sysconfdir=/etc \
--bindir=/usr/bin \
--sbindir=/usr/bin \
--disable-quiet-build \
--with-mcs-docs=no
make
# Build jay
cd "${srcdir}"/${_pkgname}-${pkgver}/mcs/jay
make
}
package() {
cd "${srcdir}"/${_pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
# Install jay
pushd "${srcdir}"/${_pkgname}-${pkgver}/mcs/jay
make DESTDIR="${pkgdir}" \
prefix=/usr \
INSTALL=../../install-sh \
install
popd
# Install binfmt conf file and pathes
install \
-m644 \
-D "${srcdir}"/mono.binfmt.d "${pkgdir}"/usr/lib/binfmt.d/mono.conf
# Install license
mkdir \
-p "${pkgdir}"/usr/share/licenses/"${_pkgname}"
install \
-m644 \
-D "LICENSE" "${pkgdir}"/usr/share/licenses/"${_pkgname}"/
# Fix .pc file to be able to request mono on what it depends,
# fixes #go-oo build
sed \
-i \
-e "s:#Requires:Requires:" "${pkgdir}"/usr/lib/pkgconfig/mono.pc
}
|