blob: 685d38fc93f0521b95de86f432d34b0a6d763a35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Serge K <arch@phnx47.net>
# For Issues, Pull Requests
# https://github.com/phnx47/pkgbuilds
_pkgname=moon
pkgname="${_pkgname}-bin"
pkgdesc='Task runner and repo management tool for the web ecosystem'
pkgver=1.22.8
pkgrel=1
license=('MIT')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
url='https://github.com/moonrepo/moon'
arch=('x86_64' 'aarch64')
depends=('gcc-libs')
source=("LICENSE::https://raw.githubusercontent.com/moonrepo/moon/v${pkgver}/LICENSE")
source_x86_64=("${_pkgname}-${pkgver}-${arch[0]}.bin::${url}/releases/download/v${pkgver}/moon-${arch[0]}-unknown-linux-gnu")
source_aarch64=("${_pkgname}-${pkgver}-${arch[1]}.bin::${url}/releases/download/v${pkgver}/moon-${arch[1]}-unknown-linux-gnu")
sha256sums=('d2ac84cff76ea43a70d2be1ba690fc03d51a9be8e8fc18281a229ddc5845e4a5')
sha256sums_x86_64=('477a3949c18556f97d7d5e3b96076512b3b4d95e2126209a0cf48c00ee0cee4c')
sha256sums_aarch64=('7b2a333f218b7713e6cfdfeedc019876839ffec8e5060af9c2294431bd006af1')
prepare() {
mkdir -p completions
chmod +x "${_pkgname}-${pkgver}-${CARCH}.bin"
"./${_pkgname}-${pkgver}-${CARCH}.bin" completions --shell bash >"completions/bash"
"./${_pkgname}-${pkgver}-${CARCH}.bin" completions --shell zsh >"completions/zsh"
"./${_pkgname}-${pkgver}-${CARCH}.bin" completions --shell fish >"completions/fish"
}
package() {
install -Dm 755 "${_pkgname}-${pkgver}-${CARCH}.bin" "${pkgdir}/usr/bin/${_pkgname}"
install -Dm 644 "LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -Dm 644 "completions/bash" "${pkgdir}/usr/share/bash-completion/completions/${_pkgname}"
install -Dm 644 "completions/zsh" "${pkgdir}/usr/share/zsh/site-functions/_${_pkgname}"
install -Dm 644 "completions/fish" "${pkgdir}/usr/share/fish/vendor_completions.d/${_pkgname}.fish"
}
|