blob: f545a51aec0f104b770c43536d4728fbc3299be9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Levente Polyak <levente[at]leventepolyak[dot]net>
_pkgname=moonlight
pkgname=${_pkgname}-git
pkgver=0.6.0.383.16fbe17
pkgrel=1
pkgdesc="Open source implementation of NVIDIA's GameStream, as used by the NVIDIA Shield"
url="http://moonlight-stream.com"
arch=('x86_64' 'i686')
license=('GPL3')
depends=('java-runtime' 'sh')
makedepends=('git' 'apache-ant')
provides=('moonlight')
conflicts=("moonlight")
source=(${pkgname}::git+https://github.com/moonlight-stream/moonlight-pc)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" "$(git describe --tags --abbrev=0|cut -dv -f2)" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname}
cat > ${_pkgname} <<EOF
#!/bin/sh
exec /usr/bin/java -jar "/usr/share/java/${_pkgname}/${_pkgname}.jar" "\$@"
EOF
}
build() {
cd ${pkgname}
if [ "${CARCH}" == "x86_64" ]; then
ant limelight-lin64
elif [ "${CARCH}" == "i686" ]; then
ant limelight-lin32
fi
}
package() {
cd ${pkgname}
if [ "${CARCH}" == "x86_64" ]; then
install -Dm 644 ./build/limelight-lin64.jar "${pkgdir}/usr/share/java/${_pkgname}/${_pkgname}.jar"
elif [ "${CARCH}" == "i686" ]; then
install -Dm 644 ./build/limelight-lin32.jar "${pkgdir}/usr/share/java/${_pkgname}/${_pkgname}.jar"
fi
install -Dm 755 ${_pkgname} "${pkgdir}/usr/bin/${_pkgname}"
install -Dm 644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}
# vim: ts=2 sw=2 et:
|