PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: ARKye03 <rafa03-dev@proton.me>

pkgname=morghulis-git
pkgver=v0.12.0.r11.g731991c
pkgrel=1
pkgdesc="Wayland GTK4 Desktop Shell (Development Version)"
arch=(x86_64)
license=('MIT')
url="https://github.com/ARKye03/morghulis"
depends=(
	gtk4
	gtk4-layer-shell
	glib2
	libnm
	libadwaita
	libastal-mpris-git
	libastal-notifd-git
	libastal-network-git
	libastal-wireplumber-git
	libastal-tray-git
	libastal-apps-git
	libastal-bluetooth-git
	libastal-battery-git
	libastal-powerprofiles-git
	libgtop
	gsound
)
optdepends=(
	'libastal-hyprland-git: Hyprland support'
	'libastal-river-git: River support'
)
makedepends=(
	git
	gobject-introspection
	vala
	meson
	dart-sass
	blueprint-compiler
)
source=("${pkgname}::git+${url}")
sha256sums=('SKIP')
install=morghulis.install
provides=('morghulis')
conflicts=('morghulis')

pkgver() {
	cd "$pkgname" || exit
	git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	cd "$pkgname" || exit
  arch-meson build
	meson compile -C build
}

package() {
	cd "$pkgname" || exit
	meson install -C build --destdir "$pkgdir"
}