blob: 2d805f76da3cdb49583b9bfaf064a13466e060f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Contributor: Butui Hu <hot123tea123@gmail.com>
pkgname=motrix-git
_pkgname=Motrix
pkgver=1.8.19.r30.g7012040
_electronversion=22
_nodeversion=16
pkgrel=1
pkgdesc="A full-featured download manager that supports downloading HTTP, FTP, BitTorrent, Magnet, etc."
arch=('any')
url="https://motrix.app/"
_ghurl="https://github.com/agalwood/Motrix"
_giteeurl="https://gitee.com/mirrors/motrix"
license=('MIT')
provides=("${pkgname%-git}=${pkgver}")
conflicts=("${pkgname%-git}")
depends=(
"electron${_electronversion}"
)
makedepends=(
'gendesk'
'git'
'yarn'
'npm'
'nvm'
)
source=(
"${pkgname%-git}::git+${_giteeurl}.git"
"${pkgname%-git}.sh"
)
sha256sums=('SKIP'
'8915ca75d453698df81f7f3305cce6869f4261d754d90f0c3724b73c7b24ca84')
pkgver() {
cd "${srcdir}/${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
_ensure_local_nvm() {
export NVM_DIR="${srcdir}/.nvm"
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
nvm install "${_nodeversion}"
nvm use "${_nodeversion}"
}
build() {
sed -e "s|@electronversion@|${_electronversion}|" \
-e "s|@appname@|${pkgname%-git}|g" \
-e "s|@appasar@|app|g" \
-i "${srcdir}/${pkgname%-git}.sh"
_ensure_local_nvm
gendesk -q -f -n --categories "Network" --name "${_pkgname}" --exec "${pkgname%-git}"
cd "${srcdir}/${pkgname%-git}"
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
sed '157,178d' -i electron-builder.json
yarn install --cache-folder "${srcdir}/.yarn_cache"
yarn lint:fix
yarn build
yarn pack
}
package() {
install -Dm755 "${srcdir}/${pkgname%-git}.sh" "${pkgdir}/usr/bin/${pkgname%-git}"
case "${CARCH}" in
x86_64)
_architecture="linux-unpacked"
;;
aarch64)
_architecture="linux-arm64-unpacked"
;;
armv7h)
_architecture="linux-armv7l-unpacked"
;;
esac
install -Dm644 "${srcdir}/${pkgname%-git}/release/${_architecture}/resources/app.asar" -t "${pkgdir}/usr/lib/${pkgname%-git}"
install -Dm755 "${srcdir}/${pkgname%-git}/release/${_architecture}/resources/engine/aria2c" -t "${pkgdir}/usr/lib/${pkgname%-git}/engine"
install -Dm644 "${srcdir}/${pkgname%-git}/release/${_architecture}/resources/engine/aria2.conf" -t "${pkgdir}/usr/lib/${pkgname%-git}/engine"
install -Dm644 "${srcdir}/${pkgname%-git}.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 "${srcdir}/${pkgname%-git}/static/512x512.png" "${pkgdir}/usr/share/pixmaps/${pkgname%-git}.png"
install -Dm644 "${srcdir}/${pkgname%-git}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|