blob: a89744321260484a605a96412f10e16686494324 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
# Maintainer: Nocifer <apmichalopoulos at gmail dot com>
# Contributor: UTUMI Hirosi <utuhiro78 at yahoo dot co dot jp>
# Contributor: Felix Yan <felixonmars@gmail.com>
# Contributor: ponsfoot <cabezon dot hashimoto at gmail dot com>
#NOTE: The UT dictionary's project page: http://linuxplayers.g1.xrea.com/mozc-ut.html
ENABLED_DICTIONARIES=(
'alt-cannadic'
'edict2'
'jawiki'
'neologd'
'personal-names'
'place-names'
'skk-jisyo'
'sudachidict'
)
pkgname='mozc-ut'
pkgver=2.30.5432.102.20240407
pkgrel=1
pkgdesc='The Open Source edition of Google Japanese Input bundled with the UT dictionary'
arch=('x86_64')
url='https://github.com/google/mozc'
license=('Apache-2.0 AND BSD-2-Clause AND BSD-3-Clause AND CC0-1.0 AND CC-BY-SA-3.0 AND CC-BY-SA-4.0 AND GPL-2.0-only AND GPL-2.0-or-later AND MIT AND NAIST-2003 AND Unicode-3.0 AND LicenseRef-Okinawa-Dictionary')
depends=('qt6-base')
makedepends=('bazel' 'git' 'python' 'rsync' 'ruby' 'wget')
optdepends=('fcitx5-mozc-ut: Fcitx5 integration'
'ibus-mozc: IBus integration'
'emacs-mozc: Emacs integration')
provides=('mozc=2.30.5432.102')
conflicts=('mozc')
options=(!distcc !ccache)
source=("${pkgname}-git::git+https://github.com/google/mozc.git#commit=548e7c3e5a0bedbf98daf634732062f7e8e47b4b"
'git+https://github.com/utuhiro78/merge-ut-dictionaries.git#commit=158abdb3f021c5b934deb9bdb17f419260d61ae8'
'git+https://github.com/utuhiro78/mozcdic-ut-alt-cannadic.git#commit=4e548e6356b874c76e8db438bf4d8a0b452f2435'
'git+https://github.com/utuhiro78/mozcdic-ut-edict2.git#commit=16283aa0c2d394a3a000eca4fa3e95eb365698c6'
'git+https://github.com/utuhiro78/mozcdic-ut-jawiki.git#commit=3fa66106b3bdb01c9b0c24dd54331d5a090082f5'
'git+https://github.com/utuhiro78/mozcdic-ut-neologd.git#commit=bf9d0d217107f2fb2e7d1a26648ef429d9fdcd27'
'git+https://github.com/utuhiro78/mozcdic-ut-personal-names.git#commit=3c115668c578992cfcac363bd7aaa0e4d0d9c72e'
'git+https://github.com/utuhiro78/mozcdic-ut-place-names.git#commit=2d4aa706c0d59f42618bbaa42a680a240bd636f6'
'git+https://github.com/utuhiro78/mozcdic-ut-skk-jisyo.git#commit=ee94f6546ce52edfeec0fd203030f52d4d99656f'
'git+https://github.com/utuhiro78/mozcdic-ut-sudachidict.git#commit=55f61c3fca81dec661c36c73eb29b2631c8ed618'
'https://dumps.wikimedia.org/jawiki/20240401/jawiki-20240401-all-titles-in-ns0.gz')
noextract=('jawiki-20240401-all-titles-in-ns0.gz')
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'9f10561ee648295807637d8b1d6faafa840e71e6566ed5ed840f4a68cf90add4')
prepare() {
cd ${pkgname}-git/src
git submodule update --init --recursive
cd "${srcdir}"/merge-ut-dictionaries/src/
# Use our local copy of the Mozc repo
sed -i -e "s|https://raw.githubusercontent.com/google/mozc/master/src|${srcdir}/${pkgname}-git/src|" remove_duplicate_ut_entries.rb
# Use a dated snapshot for the JAWiki dump data
sed -i -e '/wget/d' count_word_hits.rb
sed -i -e "s|filename = \"jawiki-|filename = \"${srcdir}/jawiki-|g" count_word_hits.rb
sed -i -e 's|jawiki-[a-z0-9]\{6,8\}|jawiki-20240401|g' count_word_hits.rb apply_word_hits.rb
# Compile the UT dictionary
printf '\nCompiling the UT dictionary...\n\n'
[[ -e mozcdic-ut.txt ]] && rm mozcdic-ut.txt
for dict in "${ENABLED_DICTIONARIES[@]}"
do
tar -xf "${srcdir}"/mozcdic-ut-${dict}/mozcdic-ut-${dict}.txt.tar.bz2
cat mozcdic-ut-${dict}.txt >> mozcdic-ut.txt
done
ruby remove_duplicate_ut_entries.rb mozcdic-ut.txt
ruby count_word_hits.rb
ruby apply_word_hits.rb mozcdic-ut.txt
# Append the UT dictionary
cat mozcdic-ut.txt >> "${srcdir}"/${pkgname}-git/src/data/dictionary_oss/dictionary00.txt
}
build() {
cd ${pkgname}-git/src
unset ANDROID_NDK_HOME
unset ANDROID_HOME
export JAVA_HOME='/usr/lib/jvm/java-11-openjdk/'
bazel build server:mozc_server gui/tool:mozc_tool --config oss_linux --compilation_mode opt
}
package() {
cd ${pkgname}-git/src
# BSD-3-Clause
sed -n 67,94p data/installer/credits_en.html > Mozc
install -Dm644 Mozc "${pkgdir}"/usr/share/licenses/mozc/Mozc
# BSD-3-Clause
sed -n 317,344p data/installer/credits_en.html > Breakpad
install -Dm644 Breakpad "${pkgdir}"/usr/share/licenses/mozc/Breakpad
# NAIST-2003
sed -n 355,424p data/installer/credits_en.html > IPAdic
install -Dm644 IPAdic "${pkgdir}"/usr/share/licenses/mozc/IPAdic
# BSD-2-Clause
sed -n 435,457p data/installer/credits_en.html > Japanese-Usage-Dictionary
install -Dm644 Japanese-Usage-Dictionary "${pkgdir}"/usr/share/licenses/mozc/Japanese-Usage-Dictionary
# Public Domain Data
sed -n 468,470p data/installer/credits_en.html > Okinawa-Dictionary
install -Dm644 Okinawa-Dictionary "${pkgdir}"/usr/share/licenses/mozc/Okinawa-Dictionary
# BSD-3-Clause
sed -n 481,513p data/installer/credits_en.html > Protocol-Buffers
install -Dm644 Protocol-Buffers "${pkgdir}"/usr/share/licenses/mozc/Protocol-Buffers
# MIT
sed -n 698,704p data/installer/credits_en.html > Tamachi-Phonetic-Kanji-Alphabet
install -Dm644 Tamachi-Phonetic-Kanji-Alphabet "${pkgdir}"/usr/share/licenses/mozc/Tamachi-Phonetic-Kanji-Alphabet
# MIT
sed -n 762,782p data/installer/credits_en.html > Windows-Implementation-Library
sed -i -e 's|^[ \t]*||g' Windows-Implementation-Library
install -Dm644 Windows-Implementation-Library "${pkgdir}"/usr/share/licenses/mozc/Windows-Implementation-Library
install -Dm755 bazel-bin/server/mozc_server "${pkgdir}"/usr/lib/mozc/mozc_server
install -Dm755 bazel-bin/gui/tool/mozc_tool "${pkgdir}"/usr/lib/mozc/mozc_tool
}
|