blob: 60e11fe042d962c23d4536296c0bfb12e40bb19b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Contributor: Lex Black <autumn-wind@web.de>
# Contributor: Filip <fila pruda com>
pkgname=mp3directcut
pkgver=2.27
pkgrel=1
pkgdesc="fast audio editor and recorder for mp3 with no need to decompress"
arch=('i686' 'x86_64')
url="http://mpesch3.de1.cc/mp3dc.html"
license=('FREEWARE')
depends_i686=(wine mpg123)
depends_x86_64=(wine lib32-mpg123)
optdepends_i686=('libpulse: PulseAudio plugin')
optdepends_x86_64=('lib32-libpulse: PulseAudio plugin')
source=(http://ftp.elf.stuba.sk/pub/pc/sound/mp3dc${pkgver/.}.exe
mp3directcut
mp3directcut.desktop
mp3dcicon.png)
md5sums=('506569cc40b1f2969645571f2cdaae8c'
'31de44159649baddf5c7b6936b87133f'
'910ada5caa9b0ea67a88bfc7ffe9c237'
'81a5bbd5789094b4bf5822791826c162')
package() {
#bin
install -Dm755 "mp3directcut" "$pkgdir/usr/bin/mp3directcut"
#app
install -d -m755 "$pkgdir/usr/share/mp3directcut"
install -m644 "mp3DirectCut.exe" "$pkgdir/usr/share/mp3directcut"
install -d -m755 "$pkgdir/usr/share/mp3directcut/Languages"
cp -r "Languages/." "$pkgdir/usr/share/mp3directcut/Languages"
#.desktop icon
install -Dm644 "mp3directcut.desktop" "$pkgdir/usr/share/applications/mp3directcut.desktop"
install -Dm644 "mp3dcicon.png" "$pkgdir/usr/share/pixmaps/mp3directcut.png"
#docs
install -d -m755 "$pkgdir/usr/share/doc/mp3directcut"
install -m644 *.txt *.htm "$pkgdir/usr/share/doc/mp3directcut"
}
|