summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 39f7355f5604b9a83d561f889f5522a2ae64da6b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=mpfr-svn
pkgver=r13491
pkgrel=1
pkgdesc="C library for multiple-precision floating-point computations with correct rounding"
arch=('i686' 'x86_64')
url="https://www.mpfr.org/"
license=('GPL3' 'LGPL3')
depends=('glibc' 'gmp')
makedepends=('subversion')
provides=('mpfr')
conflicts=('mpfr')
options=('staticlibs')
source=("svn+https://scm.gforge.inria.fr/anonscm/svn/mpfr/trunk")
sha256sums=('SKIP')


pkgver() {
  cd "trunk"

  _ver="$(svnversion)"
  printf "r%s" "${_ver//[[:alpha:]]}"
}

build() {
  cd "trunk"

  ./autogen.sh || true
  automake -a
  ./configure \
    --prefix="/usr" \
    --enable-thread-safe
  make
}

check() {
  cd "trunk"

  make check
}

package() {
  cd "trunk"

  make DESTDIR="$pkgdir" install
}