blob: 0e0c470d9de4002ee7091bdc09b8ee49f9eaed0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
|
# Maintainer: F Carpano < gmail-com: daert781 >
## NOTE: This PKGBUILD is a modified version of mpv-full-git.
## NOTE: It requires ffmpeg-git-nc, a nonconflicting version of ffmpeg-full-git.
pkgname=mpv-git-nc
_pkgname=mpv-git
pkgver=0.29.1.r353.g65b1c2d065
pkgrel=1
pkgdesc='A free, open source, and cross-platform media player (git version with all possible libs)'
arch=('x86_64')
license=('GPL3')
url='https://mpv.io/'
depends=(
# official repositories:
'lcms2' 'libcdio-paranoia' 'libgl' 'libxss'
'libxinerama' 'libxv' 'libxkbcommon' 'libva' 'wayland' 'libcaca'
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils' 'lua52' 'libdvdnav'
'libxrandr' 'jack' 'rubberband' 'uchardet' 'libarchive' 'smbclient'
'zlib' 'vapoursynth' 'sndio' 'openal' 'vulkan-icd-loader' 'shaderc'
'libplacebo'
# AUR:
'ffmpeg-git-nc' 'mujs' 'rsound' 'spirv-cross'
)
makedepends=('git' 'mesa' 'python-docutils' 'ladspa' 'vulkan-headers'
'wayland-protocols' 'ffnvcodec-headers')
optdepends=('youtube-dl: for video-sharing websites playback'
'nvidia-utils: for hardware accelerated video decoding with CUDA')
provides=('mpv')
conflicts=('mpv' 'mpv-git' 'mpv-full-git')
options=('!emptydirs')
source=("$_pkgname"::'git+https://github.com/mpv-player/mpv.git')
sha512sums=('SKIP')
pkgver() {
cd "$_pkgname"
local _version
local _revision
local _shorthash
_version="$(git tag | sort -Vr | head -n1 | sed 's/^v//')"
_revision="$(git rev-list v"${_version}"..HEAD --count)"
_shorthash="$(git rev-parse --short HEAD)"
printf '%s.r%s.g%s' "$_version" "$_revision" "$_shorthash"
}
build() {
cd "$_pkgname"
export PKG_CONFIG_PATH="/usr/lib/ffmpeg-git-nc/pkgconfig"
msg2 'Running bootstrap. Please wait...'
./bootstrap.py
./waf configure \
--color='yes' \
--prefix='/usr' \
--progress \
--confdir='/etc/mpv' \
\
--disable-lgpl \
--enable-libmpv-shared \
--disable-libmpv-static \
--disable-static-build \
--disable-debug-build \
\
--enable-manpage-build \
--disable-html-build \
--disable-pdf-build \
\
--enable-cplugins \
--enable-zsh-comp \
--disable-test \
--disable-clang-database \
\
--disable-android \
--disable-egl-android \
--disable-swift \
--disable-uwp \
--disable-win32-internal-pthreads \
--enable-iconv \
--enable-libsmbclient \
--enable-lua \
--enable-javascript \
--enable-libass \
--enable-libass-osd \
--enable-zlib \
--enable-libbluray \
--enable-dvdread \
--enable-dvdnav \
--enable-cdda \
--enable-uchardet \
--enable-rubberband \
--enable-lcms2 \
--enable-vapoursynth \
--enable-vapoursynth-lazy \
--enable-libarchive \
--enable-libavdevice \
--lua='52arch' \
\
--enable-sdl2 \
--enable-oss-audio \
--enable-rsound \
--enable-sndio \
--enable-pulse \
--enable-jack \
--enable-openal \
--disable-opensles \
--enable-alsa \
--disable-coreaudio \
--disable-audiounit \
--disable-wasapi \
\
--disable-cocoa \
--enable-drm \
--enable-drmprime \
--enable-gbm \
--enable-wayland-scanner \
--enable-wayland-protocols \
--enable-wayland \
--enable-x11 \
--enable-xv \
--disable-gl-cocoa \
--enable-gl-x11 \
--enable-egl-x11 \
--enable-egl-drm \
--enable-gl-wayland \
--disable-gl-win32 \
--disable-gl-dxinterop \
--disable-egl-angle \
--disable-egl-angle-lib \
--disable-egl-angle-win32 \
--enable-vdpau \
--enable-vdpau-gl-x11 \
--enable-vaapi \
--enable-vaapi-x11 \
--enable-vaapi-wayland \
--enable-vaapi-drm \
--enable-vaapi-glx \
--enable-vaapi-x-egl \
--enable-caca \
--enable-jpeg \
--disable-direct3d \
--enable-shaderc \
--enable-spirv-cross \
--disable-d3d11 \
--disable-rpi \
--disable-ios-gl \
--enable-plain-gl \
--disable-mali-fbdev \
--enable-gl \
--enable-libplacebo \
--enable-vulkan \
\
--disable-videotoolbox-gl \
--disable-d3d-hwaccel \
--disable-d3d9-hwaccel \
--disable-gl-dxinterop-d3d9 \
--enable-cuda-hwaccel \
\
--enable-tv \
--enable-tv-v4l2 \
--enable-libv4l2 \
--enable-audio-input \
--enable-dvbin \
\
--disable-apple-remote \
--disable-macos-touchbar \
--disable-macos-cocoa-cb
./waf build
}
package() {
cd "$_pkgname"
./waf install --destdir="$pkgdir"
install -m644 DOCS/{encoding.rst,tech-overview.txt} "${pkgdir}/usr/share/doc/mpv"
}
|