PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: alsogamer <me@alsogamer.com>
pkgname=mpv-manager
pkgver=1.2.0
pkgrel=1
pkgdesc='MPV media player installer and manager with Web UI, TUI, and CLI modes'
arch=('x86_64' 'aarch64')
url='https://gitgud.io/mike/mpv-manager'
license=('MIT')
makedepends=('go')
optdepends=('mpv: media player managed and configured by this tool'
            'celluloid: GTK-based mpv frontend'
            'mpc-qt: Qt-based mpv frontend'
            'ffmpeg: additional media processing support'
            'flatpak: manage Flatpak versions of mpv and Celluloid')
source=("${pkgname}-${pkgver}.tar.gz::https://gitgud.io/mike/mpv-manager/-/archive/v${pkgver}/mpv-manager-v${pkgver}.tar.gz")
sha256sums=('94425ccd743242870e57fbbe6e18571b5442a0272c7720bf9c8d13a5a318a168')

prepare() {
    cd "${pkgname}-v${pkgver}"
    export GOPATH="${srcdir}/gopath"
    go mod download
}

build() {
    cd "${pkgname}-v${pkgver}"
    export GOPATH="${srcdir}/gopath"
    go build \
        -trimpath \
        -buildvcs=false \
        -mod=readonly \
        -ldflags "-s -w \
            -X gitgud.io/mike/mpv-manager/pkg/version.SelfUpdateDisabled=true \
            -X gitgud.io/mike/mpv-manager/pkg/version.CurrentVersion=${pkgver} \
            -X gitgud.io/mike/mpv-manager/pkg/version.BuildTime=$(date -u +%Y-%m-%dT%H:%M:%SZ) \
            -X gitgud.io/mike/mpv-manager/pkg/version.GitCommit=release" \
        -o dist/mpv-manager \
        ./cmd/mpv-manager
}

package() {
    cd "${pkgname}-v${pkgver}"
    install -Dm755 dist/mpv-manager "${pkgdir}/usr/bin/mpv-manager"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}