blob: f90aa0e90764caed7f7bfb23da1cbee080b32096 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id: PKGBUILD 183309 2016-07-19 18:14:46Z alucryd $
# Maintainer: Christian Hesse <mail@eworm.de>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Eivind Uggedal <eivind@uggedal.com>
pkgname=mpv-sndio
_basepkg=mpv
epoch=1
pkgver=0.21.0
pkgrel=1
_waf_version=1.8.12
pkgdesc='a free, open source, and cross-platform media player (with sndio support)'
arch=('i686' 'x86_64')
license=('GPL')
url='http://mpv.io'
depends=(
'ffmpeg' 'lcms2' 'libcdio-paranoia' 'libgl' 'enca' 'libxss'
'libxinerama' 'libxv' 'libxkbcommon' 'libva' 'wayland' 'libcaca'
'desktop-file-utils' 'hicolor-icon-theme' 'xdg-utils' 'lua52' 'libdvdnav'
'libxrandr' 'jack' 'smbclient' 'rubberband'
'sndio'
)
makedepends=('mesa' 'python-docutils' 'ladspa' 'hardening-wrapper')
optdepends=('youtube-dl: for video-sharing websites playback')
conflicts=('mpv')
provides=('mpv')
options=('!emptydirs' '!buildflags')
source=("$_basepkg-$pkgver.tar.gz::https://github.com/mpv-player/$_basepkg/archive/v$pkgver.tar.gz"
"http://www.freehackers.org/~tnagy/release/waf-${_waf_version}")
sha256sums=('d05f8ece859c500ef1649cdfea911ec1529df1898b8fda3e217766dc28dc9bd3'
'01bf2beab2106d1558800c8709bc2c8e496d3da4a2ca343fe091f22fca60c98b')
prepare() {
cd ${_basepkg}-${pkgver}
install -m755 "${srcdir}"/waf-${_waf_version} waf
}
build() {
cd ${_basepkg}-${pkgver}
./waf configure --prefix=/usr \
--confdir=/etc/mpv \
--enable-cdda \
--enable-encoding \
--enable-libmpv-shared \
--enable-zsh-comp \
--enable-sndio
./waf build
}
package() {
cd ${_basepkg}-${pkgver}
./waf install --destdir="$pkgdir"
install -m644 DOCS/{encoding.rst,tech-overview.txt} \
"$pkgdir"/usr/share/doc/mpv
}
|