PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Erik Bročko <erik.brocko@letemsvetemapplem.eu>

pkgname=mshv
pkgver=258
pkgrel=3
pkgdesc="Amateur radio software by LZ2HV for digital modes MSK, JTMS, FSK, ISCAT, JT6M, FT8/4, JT65, PI4, Q65."
arch=('any')
url="http://lz2hv.org/mshv"
license=('GPL3')
depends=('fftw' 'alsa-lib' 'libpulse' 'qt5-base' 'qt5-websockets' 'hamradio-menus')
makedepends=()
conflicts=('mshv')
provides=('mshv')
source=(
	"https://downloads.sourceforge.net/project/mshv/MSHV_${pkgver}_Full_Source_Code.zip"
	"mshv_launcher.sh"
	"mshv.desktop"
	"flrigxml.patch"
)
sha256sums=(
	'039c4d432010fdae0805a023960145038c6ae780f7c439d77514aff6cf80cf1d'
	'5ccd21e3d585efb4f37aff8a3470aefa78a8689dad3b00334b9a8467840adbab'
	'85c256463746cb8a06ff1eee71677dcbe1d1c54d7aaf0f27156ebe9632269dba'
	'22de199636d17912738651eba8db6b5ccf7cecae816dcddee6d46a33d585f8ca'
)

prepare() {
	patch --directory="$srcdir/MSHV_$pkgver" --forward --strip=1 --input="$srcdir/flrigxml.patch"
}

build() {
	cd "$srcdir/MSHV_$pkgver"

	# There doesn't seem to be any difference between the .pro files apart from absolute paths
	# passed to the linker for some libraries. We'll just rely on ld to find the libraries.
	qmake MSHV_x86_64.pro PREFIX=/usr
	make
}

package() {
	cd "$srcdir"
	install -D -m755 mshv_launcher.sh "$pkgdir/usr/bin/mshv"
	install -D -m644 mshv.desktop "$pkgdir/usr/share/applications/mshv.desktop"

	cd "$srcdir/MSHV_$pkgver/bin"
	install -D -m755 MSHV_x86_64 "$pkgdir/usr/bin/mshv_bin"

	find . -type d -exec install -d -m755 "$pkgdir/usr/share/mshv/"{} \;
	find . ! -name 'MSHV_x86_64' -type f -exec install -D -m644 {} "$pkgdir/usr/share/mshv/"{} \;
	
	install -D -m644 settings/resources/ms_ico.png "$pkgdir/usr/share/pixmaps/mshv.png"
}