blob: 28b3ff04651a9383059d1e25f64d943d3cba84ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Orlando Arias <orlandoarias at gmail <dot> com>
_target=msp430-elf
pkgname=${_target}-binutils #-git
_pkgver=2.37
pkgver=${_pkgver}
pkgrel=1
pkgdesc="GNU binary utilities for the ${_target} target."
arch=(i686 x86_64)
options=('!libtool' '!buildflags')
url='http://www.gnu.org/software/binutils/'
license=(GPL)
depends=('zlib')
checkdepends=('dejagnu' 'bc')
source=(https://ftp.gnu.org/gnu/binutils/binutils-${pkgver}.tar.xz)
sha256sums=('820d9724f020a3e69cb337893a0b63c2db161dadcb0e06fc11dc29eb1e84a32c')
prepare() {
cd "${srcdir}/binutils-${_pkgver}"
# ensure a clean build
[[ -d binutils-build ]] && rm -rf binutils-build
mkdir binutils-build
}
build() {
cd "${srcdir}/binutils-${_pkgver}/binutils-build"
../configure --target=${_target} \
--prefix=/usr \
--disable-nls \
--program-prefix=${_target}- \
--enable-multilib \
--disable-werror \
--with-sysroot=/usr/${_target} \
--host=$CHOST \
--build=$CHOST \
--disable-shared \
--enable-lto \
--with-system-zlib \
--enable-plugins
make configure-host
make
}
check() {
cd "${srcdir}/binutils-${_pkgver}/binutils-build"
# unset LDFLAGS as testsuite makes assumptions about which ones are active
# do not abort on errors - manually check log files
make LDFLAGS="" -k check || true
}
package() {
cd "${srcdir}/binutils-${_pkgver}/binutils-build"
make DESTDIR="${pkgdir}" install
rm -f "${pkgdir}"/usr/bin/{ar,as,ld,nm,objdump,ranlib,strip,objcopy}
rm -f "${pkgdir}"/usr/lib/libiberty.a
rm -rf "${pkgdir}/usr/share/info"
}
# vim:set ts=2 sw=2 et:
|