blob: 0685194614f678df934868e3498d32f24a5b6b75 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: Orlando Arias <orlandoarias at gmail <dot> com>
_target=msp430-elf
pkgname=${_target}-binutils #-git
_pkgver=2.25.1
pkgver=${_pkgver}
#pkgver=2.25.r84308.c576455
pkgrel=3
pkgdesc="GNU binary utilities for the ${_target} target."
arch=(i686 x86_64)
options=('!libtool' '!buildflags')
url='http://www.gnu.org/software/binutils/'
license=(GPL)
depends=('zlib' 'flex')
# build from trunk
# provides=("${_target}-binutils=${_pkgver}")
# conflicts=("${_target}-binutils")
# makedepends=('git')
# source=("binutils-${_pkgver}::git+git://sourceware.org/git/binutils-gdb.git")
# sha256sums=('SKIP')
# build from source
source=(ftp://ftp.gnu.org/gnu/binutils/binutils-${pkgver}.tar.bz2
bfd-fix.patch
tc-msp430.c.patch)
sha256sums=('b5b14added7d78a8d1ca70b5cb75fef57ce2197264f4f5835326b0df22ac9f22'
'1b5e879dbd9da83a8c7f86abac5cf706b8ba48e3f0525d893a53c651e4015124'
'af639e72b33ce9a6b9f2fcb13355d27d7425f94a6fbefa3d0a377932a6786985')
# pkgver() {
# cd "${srcdir}/binutils-${_pkgver}"
# printf "${_pkgver}.r%s.%s" "$(git rev-list --count HEAD)" \
# "$(git rev-parse --short HEAD)"
#
# }
prepare() {
cd "${srcdir}/binutils-${_pkgver}"
# https://sourceware.org/bugzilla/show_bug.cgi?id=17940
patch -p1 < ../bfd-fix.patch
# update list of known MCU names
# https://sourceware.org/ml/binutils-cvs/2015-10/msg00074.html
# the list has to be in sync with gcc
patch -p1 < ../tc-msp430.c.patch
# ensure a clean build
[[ -d binutils-build ]] && rm -rf binutils-build
mkdir binutils-build
}
build() {
cd "${srcdir}/binutils-${_pkgver}/binutils-build"
../configure --target=${_target} \
--prefix=/usr \
--disable-nls \
--program-prefix=${_target}- \
--enable-multilib \
--disable-werror \
--with-sysroot=/usr/${_target} \
--host=$CHOST \
--build=$CHOST \
--disable-shared \
--enable-lto
make configure-host
make
}
check() {
cd "${srcdir}/binutils-${_pkgver}/binutils-build"
# unset LDFLAGS as testsuite makes assumptions about which ones are active
# do not abort on errors - manually check log files
make LDFLAGS="" -k check
}
package() {
cd "${srcdir}/binutils-${_pkgver}/binutils-build"
make DESTDIR="${pkgdir}" install
rm -f "${pkgdir}"/usr/bin/{ar,as,ld,nm,objdump,ranlib,strip,objcopy}
rm -f "${pkgdir}"/usr/lib/libiberty.a
rm -rf "${pkgdir}/usr/share/info"
# rm -rf "${pkgdir}/usr/share/gdb"
# rm -rf "${pkgdir}/usr/include/gdb"
}
# vim:set ts=2 sw=2 et:
|