blob: b3188512d473b697c116aaeb8617d7864f2780e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Maintainer: Orlando Arias <orlandoarias at gmail <dot> com>
_target="msp430-elf"
pkgname=${_target}-gcc
pkgver=9.3.0
_islver=0.22.1
pkgrel=1
pkgdesc="The GNU Compiler Collection for the ${_target} target."
arch=(i686 x86_64)
license=('GPL' 'LGPL')
url="http://gcc.gnu.org"
depends=("${_target}-newlib" "${_target}-binutils" 'libmpc' 'elfutils' 'zlib')
options=('staticlibs' '!buildflags' '!libtool' '!emptydirs' 'zipman' 'docs' '!strip')
conflicts=("${_target}-gcc-stage1")
replaces=("${_target}-gcc-stage1")
provides=("${_target}-gcc-stage1")
optdepends=("${_target}-libstdc++: C++ standard library support")
source=(http://isl.gforge.inria.fr/isl-${_islver}.tar.xz
ftp://gcc.gnu.org/pub/gcc/releases/gcc-${pkgver}/gcc-${pkgver}.tar.xz
gcc-use-init_array-if-needed.patch)
sha256sums=('28658ce0f0bdb95b51fd2eb15df24211c53284f6ca2ac5e897acc3169e55b60f'
'71e197867611f6054aa1119b13a0c0abac12834765fe2d81f35ac57f84f742d1'
'4dcec95ee660b2db78e8aaac6cfda48f6d10c3d016058514603b816819e722eb')
prepare() {
cd "${srcdir}/gcc-${pkgver}"
[[ -L isl ]] && rm -f isl
ln -s ../isl-${_islver} isl
[[ -d gcc-build ]] && rm -rf gcc-build
mkdir gcc-build
# From newlib 3.2.0 onwards, .init_array is used only if the required symbols
# are defined by gas. This functionality already exists in the current
# binutils (2.33.1) and is part of GCC 10. The idea is to be able to run the
# linker with --gc-sections and rid of the binary of initialization code that
# is not needed. The assembler gas will emit the necessary symbols if the
# code is actually needed. Backport the patch to the GCC 9.x series.
patch -p1 < ../gcc-use-init_array-if-needed.patch
}
build() {
cd "${srcdir}/gcc-${pkgver}"
export CFLAGS="-O2 -pipe"
export CXXFLAGS="-O2 -pipe"
export CFLAGS_FOR_TARGET="-Os -pipe"
export CXXFLAGS_FOR_TARGET="-Os -pipe"
echo ${pkgver} > gcc/BASE-VER
cd gcc-build
../configure \
--prefix=/usr \
--program-prefix=${_target}- \
--target=${_target} \
--host=$CHOST \
--build=$CHOST \
--enable-shared \
--disable-nls \
--disable-threads \
--enable-languages=c,c++ \
--enable-multilib \
--with-system-zlib \
--with-local-prefix=/usr/${_target} \
--with-sysroot=/usr/${_target} \
--with-as=/usr/bin/${_target}-as \
--with-ld=/usr/bin/${_target}-ld \
--disable-libgomp \
--disable-libssp \
--enable-interwork \
--enable-addons \
--enable-lto
make all-gcc all-target-libgcc
}
package() {
cd "${srcdir}/gcc-${pkgver}/gcc-build"
export CFLAGS="-O2 -pipe"
export CXXFLAGS="-O2 -pipe"
export CFLAGS_FOR_TARGET="-Os -pipe"
export CXXFLAGS_FOR_TARGET="-Os -pipe"
make DESTDIR="${pkgdir}" install-gcc install-target-libgcc
rm -rf "${pkgdir}/usr/share/man/man7/"
rm -rf "${pkgdir}/usr/share/info"
cp -r "${pkgdir}"/usr/libexec/* "${pkgdir}/usr/lib/"
rm -rf "${pkgdir}/usr/libexec"
# strip it manually
strip "${pkgdir}"/usr/bin/* 2>/dev/null || true
find "${pkgdir}"/usr/lib -type f -exec /usr/bin/${_target}-strip \
--strip-unneeded {} \; 2>/dev/null || true
}
# vim:set ts=2 sw=2 et:
|