blob: a77046b537e5ecb205e272f9003b927c2bdaf492 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=mtdev-git
pkgver=1.1.6.r1.g2ed588e
pkgrel=1
pkgdesc="A stand-alone library which transforms all variants of kernel MT events to the slotted type B protocol"
arch=('i686' 'x86_64')
url="https://bitmath.org/code/mtdev/"
license=('MIT')
depends=('glibc')
makedepends=('git')
provides=("mtdev=$pkgver")
conflicts=('mtdev')
options=('staticlibs')
source=("git+https://bitmath.org/git/mtdev.git")
sha256sums=('SKIP')
pkgver() {
cd "mtdev"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}
build() {
cd "mtdev"
./autogen.sh
./configure \
--prefix="/usr"
make
}
check() {
cd "mtdev"
make check
}
package() {
cd "mtdev"
make DESTDIR="$pkgdir" install
install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/mtdev"
}
|