blob: 8e0a06981e9e71740c527a42a15b6d0031bc1bb6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id$
# Maintainer: Alexey Trifonov <otaku [at] rambler dot ru>
# Contributor: Alexander F Rødseth <xyproto@archlinux.org>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: yosh64 <yosh64.at.gmail.dot.com>
pkgname=mtpaint-wjaguar
pkgver=3.49.25
pkgrel=1
_commit="298e5d72dbe0662a1b711939bbaa80a52a473d10"
pkgdesc='Simple paint program for creating icons and pixel based artwork (Dmitry Groshev''s fork)'
arch=('x86_64')
url='https://github.com/wjaguar/mtPaint'
license=('GPL3')
depends=('gtk2' 'giflib' 'openjpeg' 'lcms2' 'libwebp' 'libtiff')
optdepends=('gifsicle: for exporting GIF files from mtPaint')
provides=('mtpaint')
conflicts=('mtpaint')
source=("mtpaint-$pkgver.zip::https://github.com/wjaguar/mtPaint/archive/$_commit.zip")
sha256sums=('2a0c2f6c2fcfb07dd519c8e2c3e86aff9b2f519fdcecc9cc4a050ea528a4ab0c')
prepare() {
cd "mtPaint-$_commit"
# Recommended by Mark Tyler himself
sed -i 's:$LIBS $LDFLAGS:$LDFLAGS $LIBS:' configure
}
build() {
cd "mtPaint-$_commit"
./configure --prefix=/usr --mandir=/usr/share/man man intl GIF jpeg tiff cflags lcms2 jp2 webp
make
}
package() {
make -C "mtPaint-$_commit" DESTDIR="$pkgdir" install
}
# vim:ts=2 sw=2 et:
|