blob: e2bc58eacca2d94fda970da6574af9a94f63361f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: megadriver <megadriver at gmx dot com>
# Contributor: Tom Willemsen <tom at ryuslash dot org>
# Contributor: Uwe <moc liamg skcuneelu <-- look what I did there>
# Contributor: Nicolas Pouillard <nicolas dot pouillard at gmail dot com>
# Contributor: Vain
pkgname=mu
pkgver=0.9.16
pkgrel=1
pkgdesc="A collection of utilities for indexing and searching Maildirs"
arch=('i686' 'x86_64')
url="http://www.djcbsoftware.nl/code/mu"
license=('GPL3')
depends=('xapian-core' 'gmime' 'sqlite3')
makedepends=('webkitgtk')
optdepends=('cron: Updating index regularly'
'webkitgtk: for msg2pdf and GUI')
conflicts=('mailutils')
install=$pkgname.install
source=($pkgname-$pkgver.tar.gz::https://github.com/djcb/mu/archive/v$pkgver.tar.gz)
sha256sums=('af086880b00a6954bc1135b226b66a33205893600c8dd04139a6871c62c6f05c')
prepare() {
cd "${srcdir}"/$pkgname-$pkgver/toys/mug
sed -i 's|MUGDIR|"/usr/share/pixmaps"|g' mug.c
}
build() {
cd "${srcdir}"/$pkgname-$pkgver
# msg2pdf and mug will be built only if webkitgtk is installed
autoreconf --force --install
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}"/$pkgname-$pkgver
make DESTDIR="${pkgdir}" install
# if msg2pdf and mug were built, install them
# if not, remove the unneeded mug manpage
if [ -f toys/msg2pdf/msg2pdf ]; then
install -m755 toys/msg2pdf/msg2pdf "${pkgdir}"/usr/bin/msg2pdf
fi
if [ -f toys/mug/mug ]; then
install -m755 toys/mug/mug "${pkgdir}"/usr/bin/mug
install -Dm644 toys/mug/mug.svg "${pkgdir}"/usr/share/pixmaps/mug.svg
else
rm "${pkgdir}"/usr/share/man/man1/mug.1
fi
}
|