blob: 4cb7e2af4eff5d43012f4f4177da01a00fdce8a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: David Birks <david at tellus dot space>
# Contributor: Jeff Henson <jeff at henson dot io>
# Contributor: Linus Färnstrand <linus at mullvad dot net>
# Contributor: Emīls Piņķis <emil at mullvad dot net>
# Contributor: Andrej Mihajlov <and at mullvad dot net>
pkgname=mullvad-vpn-beta
_pkgver=2022.5
_channel=stable
_rel=1
# beta
#pkgver=${_pkgver}.${_channel}${_rel}
# stable
pkgver=${_pkgver}.${_channel}
pkgrel=2
pkgdesc="The Mullvad VPN client app for desktop (beta channel)"
arch=('x86_64' 'aarch64')
url="https://www.mullvad.net"
license=('GPL3')
depends=('iputils' 'libnotify' 'libappindicator-gtk3' 'nss')
makedepends=('cargo' 'git' 'go' 'nodejs>=16' 'npm>=8.3' 'libxcrypt-compat')
provides=("${pkgname%-beta}")
conflicts=("${pkgname%-beta}")
options=('!lto')
install="${pkgname%-beta}.install"
_tag=5bcd2533633d76b1deaf5875b24a2c83bec6fc49 # tags/2022.5^0
_commit=f6dca66645c82501a330416ad39c7e63bcdae57d
source=("git+https://github.com/mullvad/mullvadvpn-app.git#commit=${_tag}?signed"
"git+https://github.com/mullvad/mullvadvpn-app-binaries.git#commit=${_commit}?signed"
'no-rpm.diff'
"${pkgname%-beta}.sh")
sha256sums=('SKIP'
'SKIP'
'ea35edffea2cbbb05586abce19581fdd9f133801ed47e6af30fa64a29c5cf116'
'a59c29f07b4eab9af56f0e8be42bae0d83726f5185e88de0c5a48f4098c3c0a4')
validpgpkeys=('EA0A77BF9E115615FC3BD8BC7653B940E494FE87' # Linus Färnstrand (code signing key) <linus@mullvad.net>
'8339C7D2942EB854E3F27CE5AEE9DECFD582E984' # David Lönnhager (code signing) <david.l@mullvad.net>
'4B986EF5222BA1B810230C602F391DE6B00D619C') # Oskar Nyberg (code signing) <oskar@mullvad.net>
prepare() {
cd "$srcdir/mullvadvpn-app"
git submodule init
git config submodule.dist-assets/binaries.url "$srcdir/mullvadvpn-app-binaries"
git -c protocol.file.allow=always submodule update
# Disable building of rpm
patch --strip=1 gui/tasks/distribution.js < ../no-rpm.diff
export RUSTUP_TOOLCHAIN=stable
echo "Removing old Rust build artifacts"
cargo clean
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
pushd wireguard/libwg
export GOPATH="$srcdir/gopath"
mkdir -p "../../build/lib/$CARCH-unknown-linux-gnu"
go mod download -x
popd
pushd gui
echo "Installing JavaScript dependencies..."
export npm_config_cache="$srcdir/npm_cache"
npm ci
popd
}
build() {
cd "$srcdir/mullvadvpn-app"
local RUSTC_VERSION=$(rustc --version)
local PRODUCT_VERSION=$(cd gui/; node -p "require('./package.json').version" | sed -Ee 's/\.0//g')
echo "Building Mullvad VPN ${PRODUCT_VERSION}..."
echo "Building wireguard-go..."
pushd wireguard/libwg
export GOPATH="$srcdir/gopath"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -v -o "../../build/lib/$CARCH-unknown-linux-gnu"/libwg.a -buildmode c-archive
popd
# Clean module cache for makepkg -C
go clean -modcache
echo "Building Rust code in release mode using ${RUSTC_VERSION}..."
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
echo "Preparing for packaging Mullvad VPN ${PRODUCT_VERSION}..."
mkdir -p dist-assets/shell-completions
for sh in bash zsh fish; do
echo "Generating shell completion script for ${sh}..."
cargo run --bin mullvad --frozen --release -- shell-completions ${sh} \
dist-assets/shell-completions/
done
echo "Updating relays.json..."
cargo run --bin relay_list --frozen --release > dist-assets/relays.json
binaries=(
mullvad-daemon
mullvad
mullvad-problem-report
libtalpid_openvpn_plugin.so
mullvad-setup
mullvad-exclude
)
for binary in ${binaries[*]}; do
cp target/release/${binary} dist-assets/${binary}
done
# Build Electron GUI
pushd gui
echo "Packing Mullvad VPN ${PRODUCT_VERSION} artifact(s)..."
export npm_config_cache="$srcdir/npm_cache"
npm run pack:linux
popd
}
#check() {
# cd "$srcdir/mullvadvpn-app"
# export RUSTUP_TOOLCHAIN=stable
# cargo test --frozen
#
# cd gui
# npm test
#}
package() {
cd "$srcdir/mullvadvpn-app"
# Install main files
install -d "$pkgdir/opt/Mullvad VPN"
if [ "$CARCH" == "aarch64" ]; then
cp -r dist/linux-arm64-unpacked/* "$pkgdir/opt/Mullvad VPN/"
else
cp -r dist/linux-unpacked/* "$pkgdir/opt/Mullvad VPN/"
fi
chmod 4755 "$pkgdir/opt/Mullvad VPN/chrome-sandbox"
# Install services
install -Dm644 dist-assets/linux/mullvad{-daemon,-early-boot-blocking}.service -t \
"$pkgdir/usr/lib/systemd/system/"
# Install binaries
install -Dm755 dist-assets/{mullvad,mullvad{-daemon,-exclude}} -t "$pkgdir/usr/bin/"
# Link to the problem report binary
ln -s "/opt/Mullvad VPN/resources/mullvad-problem-report" "$pkgdir/usr/bin/"
# Link to the GUI binary
install -m755 "$srcdir/${pkgname%-beta}.sh" "$pkgdir/usr/bin/${pkgname%-beta}"
# Install completions
install -Dm644 dist-assets/shell-completions/mullvad.bash \
"$pkgdir/usr/share/bash-completion/completions/mullvad"
install -Dm644 dist-assets/shell-completions/_mullvad -t \
"$pkgdir/usr/share/zsh/site-functions/"
install -Dm644 dist-assets/shell-completions/mullvad.fish -t \
"$pkgdir/usr/share/fish/vendor_completions.d/"
# Install desktop file & icons from deb
cd dist
ar x *.deb
bsdtar -xf data.tar.xz
install -Dm644 "usr/share/applications/${pkgname%-beta}.desktop" -t \
"$pkgdir/usr/share/applications/"
for icon_size in 16 32 48 64 128 256 512 1024; do
icons_dir=usr/share/icons/hicolor/${icon_size}x${icon_size}/apps
install -Dm644 ${icons_dir}/${pkgname%-beta}.png -t "$pkgdir/${icons_dir}/"
done
}
|