blob: 852938a53009dde95bb25efe65fb33a1817df4c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Martin Diehl <aur@martin-diehl.net>
# Contributor: eDgar <eDgar |at| openmail.cc >
# Contributor: Michele Mocciola <mickele>
# Contributor: Guillaume Dollé < dolle dot guillaume at gmail dot com >
# Contributor: Lucas H. Gabrielli
pkgname=mumps
pkgver=5.6.2
pkgrel=1
pkgdesc='Sparse solver library using Gaussian elimination'
url='https://graal.ens-lyon.fr/MUMPS/index.php'
license=('custom')
depends=('lapack' 'openmpi' 'scotch' 'scalapack' 'metis' 'zlib' 'bzip2')
makedepends=('gcc-fortran')
conflicts=('mumps-par' 'mumps4')
arch=('i686' 'x86_64')
source=(http://graal.ens-lyon.fr/MUMPS/MUMPS_${pkgver}.tar.gz
Makefile.inc)
sha512sums=('5ee2659ed963ca525fc253986504250d0529257d79f18534032b970985528670cbadea023ff596829936c1b18ec6ef8925c3a6c0451eb1ad50caa88b20706adf'
'348dc692cb66f428d38808e4ec50c259a7a841d6c09ccd9fce829a731967358e7b9db2be5436b86e20539ddcc014b7c577fb5dd0d114a418a91573f49cf38ef0')
prepare () {
cd "${srcdir}/MUMPS_${pkgver}"
cp "${srcdir}/Makefile.inc" .
}
build() {
cd "${srcdir}/MUMPS_${pkgver}"
make all
}
check () {
cd "${srcdir}/MUMPS_${pkgver}/examples"
make all
# From the README (in examples)
MPIRUN="mpirun -np 3 --mca plm_rsh_agent sh --mca opal_warn_on_missing_libcuda 0 --oversubscribe"
export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}:${srcdir}/MUMPS_${pkgver}/lib"
${MPIRUN} ./ssimpletest < input_simpletest_real
${MPIRUN} ./dsimpletest < input_simpletest_real
${MPIRUN} ./csimpletest < input_simpletest_cmplx
${MPIRUN} ./zsimpletest < input_simpletest_cmplx
${MPIRUN} ./c_example
${MPIRUN} ./multiple_arithmetics_example
${MPIRUN} ./ssimpletest_save_restore < input_simpletest_real
${MPIRUN} ./dsimpletest_save_restore < input_simpletest_real
${MPIRUN} ./csimpletest_save_restore < input_simpletest_cmplx
${MPIRUN} ./zsimpletest_save_restore < input_simpletest_cmplx
${MPIRUN} ./c_example_save_restore
}
package(){
# Install all headers
cd "${srcdir}/MUMPS_${pkgver}/include"
install -d -m755 "${pkgdir}/usr/include"
install -D -m644 *.h "${pkgdir}/usr/include"
# Install all libraries
cd "${srcdir}/MUMPS_${pkgver}/lib"
install -d -m755 ${pkgdir}/usr/lib
install -D -m644 *.so ${pkgdir}/usr/lib
# Install examples
install -m 755 -d "${pkgdir}/usr/share/doc/${pkgname}/examples"
cd "${srcdir}/MUMPS_${pkgver}/examples"
install -m 644 * "${pkgdir}/usr/share/doc/${pkgname}/examples"
install -m 644 "${srcdir}/MUMPS_${pkgver}/Makefile.inc" "${pkgdir}/usr/share/doc/${pkgname}/examples"
sed -i 's_\(topdir =\).*_\1 /usr_g; s-.*\(Makefile.inc\)-include Makefile.inc-g' "${pkgdir}/usr/share/doc/${pkgname}/examples/Makefile"
# Install license
install -D -m644 "${srcdir}/MUMPS_${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|