blob: 28cba1a392c6763cc241c46363785e6fb999e006 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# # Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=musicfetch
_app_id="net.fhannenheim.$pkgname"
pkgver=1.5.1
pkgrel=1
pkgdesc="Download and tag music from YouTube"
arch=('x86_64' 'aarch64')
url="https://codeberg.org/Frieder_Hannenheim/musicfetch-ng"
license=('GPL-3.0-or-later')
depends=(
'cosmic-icon-theme'
'deno'
'libxkbcommon'
'openssl'
'vulkan-icd-loader'
'wayland'
'xdg-user-dirs'
'yt-dlp'
'yt-dlp-ejs'
)
makedepends=(
'cargo'
'just'
)
checkdepends=(
'appstream'
'desktop-file-utils'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
noextract=("$pkgname-$pkgver.tar.gz")
sha256sums=('c96c67b5559e893837aab8f854cb90fa57b7ff60bd5a4bfd351150d504704d7d')
prepare() {
mkdir -p "$pkgname-$pkgver"
bsdtar xf "$pkgname-$pkgver.tar.gz" --strip-components 1 -C "$pkgname-$pkgver"
cd "$pkgname-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target host-tuple
}
build() {
cd "$pkgname-$pkgver"
CFLAGS+=" -ffat-lto-objects"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
just build-release --frozen
}
check() {
cd "$pkgname-$pkgver"
appstreamcli validate --no-net "resources/${_app_id}.metainfo.xml"
desktop-file-validate "resources/${_app_id}.desktop"
}
package() {
cd "$pkgname-$pkgver"
just rootdir="$pkgdir" install
}
|