blob: 12917a491b7a2dd54580ad3febe6cf94da916a2b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: mrxx <mrxx at cyberhome dot at>
# Contributor: Frederic Bezies < fredbezies at gmail dot com>
# Contributor: jddolvin <jddolvin@atheist.com>
# Contributor: arriagga <ramon.arriaga@gmail.com>
# Contributor: dieghen89 <dieghen89@gmail.com>
pkgname=musique-git
pkgver=1.12.r16.gba46852
pkgrel=1
pkgdesc="A finely crafted music player"
arch=(x86_64)
url="https://flavio.tordini.org/musique"
license=(GPL3)
depends=(qt6-base qt6-declarative taglib mpv)
makedepends=(git qt6-tools)
source=("git+https://github.com/flaviotordini/musique.git"
"git+https://github.com/flaviotordini/http.git"
"git+https://github.com/flaviotordini/idle.git"
"git+https://github.com/flaviotordini/media.git"
"git+https://github.com/flaviotordini/updater.git"
"git+https://github.com/flaviotordini/js.git"
"git+https://github.com/flaviotordini/sharedcache.git"
"git+https://github.com/itay-grudev/SingleApplication.git"
"git+https://github.com/flaviotordini/qt-reusable-widgets.git")
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "musique"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "musique"
install -d build
git submodule init
git config 'submodule.lib/http.url' "${srcdir}/http"
git config 'submodule.lib/idle.url' "${srcdir}/idle"
git config 'submodule.lib/media.url' "${srcdir}/media"
git config 'submodule.lib/updater.url' "${srcdir}/updater"
git config 'submodule.lib/js.url' "${srcdir}/js"
git config 'submodule.lib/sharedcache.url' "${srcdir}/sharedcache"
git config 'submodule.lib/singleapplication.url' "${srcdir}/SingleApplication"
git config 'submodule.lib/qt-reusable-widgets.url' "${srcdir}/qt-reusable-widgets"
git -c protocol.file.allow=always submodule update
}
build() {
cd "musique/build"
PATH="$PATH:/usr/lib/qt6/bin"
qmake6 .. PREFIX=/usr
make
}
package() {
cd "musique/build"
make INSTALL_ROOT="$pkgdir" install
}
|