blob: 0b2a0744fc7e8b25da0749630fc4afcab81f4f35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Bjorn Neergaard (neersighted) <bjorn@neersighted.com>
# Contributor: boyska <piuttosto@logorroici.org>
_pkgname=mutt-kz
pkgname=mutt-kz-git
pkgver=mutt.1.6.rel.r236.g73ff2ad
pkgrel=1
pkgdesc='Small but powerful text-based mail client (experimental fork) (development version)'
url='https://github.com/karelzak/mutt-kz'
license=('GPL')
source=('git+https://github.com/karelzak/mutt-kz.git')
sha256sums=('SKIP')
arch=('i686' 'x86_64')
depends=('libidn' 'krb5' 'notmuch-runtime')
makedepends=('git' 'gnupg' 'libxslt')
conflicts=('mutt')
provides=('mutt')
pkgver() {
cd "${srcdir}/${_pkgname}"
# Get the version number.
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/${_pkgname}"
# Configure the build.
./prepare \
--prefix=/usr \
--sysconfdir=/etc \
--enable-debug \
--enable-pgp \
--enable-gpgme \
--enable-notmuch \
--enable-pop \
--enable-imap \
--enable-smtp \
--enable-hcache \
--with-gss=/usr \
--with-ssl=/usr \
--with-sasl \
--with-curses=/usr \
--with-regex \
--with-idn
# Build it!
make
}
package() {
cd "${srcdir}/${_pkgname}"
# Install the program.
make DESTDIR="${pkgdir}" install
# Cruft we don't want.
rm "${pkgdir}"/usr/bin/{flea,muttbug}
rm "${pkgdir}"/usr/share/man/man1/{flea,muttbug}.1
rm "${pkgdir}"/etc/mime.types{,.dist}
}
# vim: ft=sh ts=2 sw=2 et
|