blob: 1da63df7ccc55b5047c7d8756cc41f0ae64d27ea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Sean Greenslade <aur at seangreenslade dot com>
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Jon Gjengset
# Contributor: jsteel <mail at jsteel dot org>
# Contributor: andreas_baumann <abaumann at yahoo dot com>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: tobias [tobias [at] archlinux.org]
_pkgbase=mutt
pkgname=${_pkgbase}-slang
pkgver=2.2.9
pkgrel=1
pkgdesc="Small but very powerful text-based mail client - slang version"
arch=(x86_64)
url="http://www.mutt.org/"
license=(GPL2)
depends=(glibc libgpg-error mime-types slang sqlite zlib)
makedepends=(docbook-xml docbook-xsl elinks gdbm gpgme krb5 libidn2 libsasl
libxslt lynx openssl)
provides=(mutt)
conflicts=(mutt)
optdepends=(
'perl: for smime_keys'
'python: for experimental mutt_oath2.py'
'smtp-forwarder: to send mail'
)
backup=(etc/Muttrc)
options=(debug)
source=(https://bitbucket.org/${_pkgbase}/${_pkgbase}/downloads/${_pkgbase}-$pkgver.tar.gz{,.asc})
sha512sums=('d4d308ba573ba6e43b6dd2c131d0dc345163bd375f19a9038c9eeaf271f9da88043951f6c74658ff1a9d7a8fdcce28809aba50ab3f5aa0d34b77cf4989bc054f'
'SKIP')
b2sums=('86b0743102bb1b023b3ccb03740c24c6ec728765b3770afdb3faed2982789aaa38a7c306e5ee30ca05ced1baa7771657ab37e5ad53eaf59ec73e51990f699c74'
'SKIP')
validpgpkeys=('8975A9B33AA37910385C5308ADEF768480316BDA') # Kevin J. McCarthy <kevin@8t8.us>
prepare() {
cd "${_pkgbase}-$pkgver"
autoreconf -fiv
}
build() {
local configure_options=(
--prefix=/usr
--sysconfdir=/etc
--enable-debug
--enable-gpgme
--enable-pop
--enable-imap
--enable-smtp
--enable-hcache
--enable-sidebar
--enable-autocrypt
--with-slang=/usr
--with-gss=/usr
--with-ssl=/usr
--with-sqlite3
--with-sasl
--with-idn2
)
cd "${_pkgbase}-$pkgver"
./configure "${configure_options[@]}"
make
}
package() {
depends+=(
gdbm libgdbm.so
gpgme libgpgme.so
krb5 libgssapi_krb5.so
libidn2 libidn2.so
libsasl libsasl2.so
openssl libssl.so
)
make DESTDIR="$pkgdir" install -C ${_pkgbase}-$pkgver
install -vDm 644 ${_pkgbase}-$pkgver/contrib/gpg.rc "$pkgdir/etc/Muttrc.gpg.dist"
# /etc/mime.types is provided by mailcap
rm "$pkgdir/etc/mime.types"{,.dist}
}
|