blob: bcba8222c32d5c0037f27d3e64a465cea5175bc8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id$
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
# Patched package maintainer: Saren Arterius <saren@wtako.net>
# Patch origin: https://gist.github.com/DeadMetaler/12622bf9415c1100f2d436ffbd6778c6
pkgname=mutter-781835-workaround
_pkgname=mutter
pkgver=3.26.1+7+g41f7a5fdf
pkgrel=1
pkgdesc="A window manager for GNOME"
url="https://git.gnome.org/browse/mutter"
arch=(i686 x86_64)
license=(GPL)
depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
libcanberra startup-notification zenity libsm gnome-desktop upower
libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire)
makedepends=(intltool gobject-introspection git gnome-common)
provides=(mutter)
conflicts=(mutter)
groups=(gnome)
options=(!emptydirs)
_commit=41f7a5fdf3bd95bd13e43e2151d29157d1dc5168 # gnome-3-26
source=("git+https://git.gnome.org/browse/mutter#commit=$_commit"
startup-notification.patch
revert.patch)
sha256sums=('SKIP'
'5a35ca4794fc361219658d9fae24a3ca21a365f2cb1901702961ac869c759366'
'07f87412f2a24dc03fab95eb8aba437fad0927aad844db0557c193c811e03f88')
pkgver() {
cd $_pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $_pkgname
# https://bugs.archlinux.org/task/51940
patch -Np1 -i ../startup-notification.patch
patch -Np1 -i ../revert.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $_pkgname
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/$_pkgname --disable-static \
--disable-schemas-compile --enable-compile-warnings=minimum \
--enable-gtk-doc --enable-egl-device --enable-remote-desktop
#https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -e 's/ -shared / -Wl,-O1,--as-needed\0/g' \
-i {.,cogl,clutter}/libtool
make
}
package() {
cd $_pkgname
make DESTDIR="$pkgdir" install
}
|