blob: 3441d7c6df5e9a5be97fdadeaaa62bf073b76a43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
# Maintainer: parcimonic <aur-at_parcimonic-dot_me>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
pkgbase=mutter-auto-rotation
pkgname=mutter-auto-rotation
provides=(libmutter-11.so mutter)
conflicts=(mutter)
pkgver=43.3
pkgrel=2
pkgdesc="Window manager and compositor for GNOME, with touch-mode auto-rotation (reverts MR 1710)"
url="https://gitlab.gnome.org/GNOME/mutter"
arch=(x86_64)
license=(GPL)
depends=(
colord
dconf
gnome-desktop
gnome-settings-daemon
graphene
gsettings-desktop-schemas
lcms2
libcanberra
libgudev
libinput
libsm
libsysprof-capture
libxkbcommon-x11
libxkbfile
pipewire
startup-notification
xorg-xwayland
)
makedepends=(
egl-wayland
gi-docgen
git
gobject-introspection
meson
sysprof
wayland-protocols
xorg-server
xorg-server-xvfb
)
_commit=a63755bdad7d8bffdbbc649178d759c37dacce01 # tags/43.3^0
source=(
"git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit"
"0001-Revert-backends-native-Disable-touch-mode-with-point.patch"
)
sha256sums=(
'SKIP'
'b11e3e1c9a14b9d9a3941e4495f7f16cfe84c53c6b8e571df049546840a91a46'
)
pkgver() {
cd mutter
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd mutter
# Fix broken focus handling with XWayland
# https://gitlab.gnome.org/GNOME/mutter/-/merge_requests/2848
# git cherry-pick -n d5e75bccdee7ea0e30cd860ca08ae109dcb311c8
git apply ../0001-Revert-backends-native-Disable-touch-mode-with-point.patch
}
build() {
CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
LDFLAGS+=" -Wl,-Bsymbolic-functions"
arch-meson mutter build \
-D egl_device=true \
-D wayland_eglstream=true \
-D docs=true \
-D installed_tests=false
meson compile -C build
}
_check() (
export XDG_RUNTIME_DIR="$PWD/rdir" GSETTINGS_SCHEMA_DIR="$PWD/build/data"
mkdir -p -m 700 "$XDG_RUNTIME_DIR"
glib-compile-schemas "$GSETTINGS_SCHEMA_DIR"
pipewire &
_p1=$!
wireplumber &
_p2=$!
trap "kill $_p1 $_p2; wait" EXIT
meson test -C build --print-errorlogs -t 3
)
_check_disabled() {
dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
bash -c "$(declare -f _check); _check"
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package() {
meson install -C build --destdir "$pkgdir"
_pick docs "$pkgdir"/usr/share/mutter-*/doc
}
# vim:set sw=2 sts=-1 et:
|