blob: ea482f90aa02b42d4ebd65162298696e564031ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: Joakim Soderlund <joakim.soderlund@gmail.com>
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
pkgname=mutter-dynamic-buffering
pkgver=41.5
pkgrel=1
pkgdesc="A window manager for GNOME (with dynamic triple/double buffering)"
url="https://gitlab.gnome.org/GNOME/mutter"
arch=(x86_64)
license=(GPL)
depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
libcanberra startup-notification zenity libsm gnome-desktop upower
libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
xorg-xwayland graphene libxkbfile libsysprof-capture)
makedepends=(gobject-introspection git egl-wayland meson xorg-server
wayland-protocols sysprof)
#checkdepends=(xorg-server-xvfb pipewire-media-session python-dbusmock)
provides=(mutter libmutter-9.so)
conflicts=(mutter)
groups=(gnome)
#options=(debug)
_commit=17926e941d67867911c462737f4d013adb55e4d6 # tags/41.5^0
source=("$pkgname::git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit"
'backports.patch'
'mr1441.patch')
sha256sums=('SKIP'
'4bfebf11fd10d2829977cb3c77491bcb9eaa7779f9fc72cdbf10cb0f56adc813'
'cf99896763558258f489ff0e9a1e8001f716d63b06366f740e044cc72a71d3e7')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd "$srcdir/$pkgname"
patch -p1 < "$srcdir/mr1441.patch"
patch -p1 < "$srcdir/backports.patch"
# Make tests run
sed -i '/catchsegv/d' meson.build
}
build() {
CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
LDFLAGS+=" -Wl,-Bsymbolic-functions"
arch-meson $pkgname build \
-D egl_device=true \
-D wayland_eglstream=true \
-D installed_tests=false \
-D tests=false
meson compile -C build
}
_check_internal() (
mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
pipewire &
_p1=$!
pipewire-media-session &
_p2=$!
trap "kill $_p1 $_p2; wait" EXIT
meson test -C build --print-errorlogs
)
_check_disabled() {
dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
bash -c "$(declare -f _check_internal); _check_internal"
}
package() {
meson install -C build --destdir "$pkgdir"
}
|