blob: a3bca85acf40a4ac8349736a61fefcfe6a59d98b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
# Maintainer: Georg Wagner <puxplaying_at_gmail_dot_com>
# Contributor: @xabbu <https://github.com/xabbu>
# Contributor: Stefano Capitani <stefano_at_manjaro_dot_org>
# Contributor: Mark Wagie <mark_at_manjaro_dot_org>
# Contributor: Jonathon Fernyhough
# Contributor: realqhc <https://github.com/realqhc>
# Contributor: Brett Alcox <https://github.com/brettalcox>
# Archlinux credits:
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
# Ubuntu credits:
# Marco Trevisan: <https://salsa.debian.org/gnome-team/mutter/-/blob/ubuntu/master/debian/patches/ubuntu/x11-Add-support-for-fractional-scaling-using-Randr.patch>
pkgname=mutter-x11-scaling
pkgver=45.1
pkgrel=1
pkgdesc="Window manager and compositor for GNOME with X11 fractional scaling patch"
url="https://gitlab.gnome.org/GNOME/mutter"
arch=(x86_64)
license=(GPL)
depends=(
colord
dconf
gnome-desktop-4
gnome-settings-daemon
graphene
gsettings-desktop-schemas
iio-sensor-proxy
lcms2
libcanberra
libdisplay-info
libei
libgudev
libinput
libsm
libsysprof-capture
libxkbcommon-x11
libxkbfile
pipewire
startup-notification
xorg-xwayland
)
makedepends=(
egl-wayland
gi-docgen
git
gobject-introspection
gtk3
meson
sysprof
wayland-protocols
xorg-server
xorg-server-xvfb
)
checkdepends=(
gnome-session
python-dbusmock
wireplumber
zenity
)
provides=(mutter=$pkgver libmutter-13.so)
conflicts=(mutter)
_commit=c71a119de06d8937930e4d1adf06ff0c2b259653 # tags/45.1^0
source=(
"git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit"
"https://raw.githubusercontent.com/puxplaying/mutter-x11-scaling/mutter-45/mutter-45.0-x11-Add-support-for-fractional-scaling-using-Randr.patch"
)
b2sums=('SKIP'
'c25a4c909aa9a07d3c0a131a8419d510583ecdd883950c82ff487b0f578a13b2cb093c54b966cb48509c77ffdcc93cbadcd67318173454fb8cb424f01fd0bcb5')
pkgver() {
cd mutter
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd mutter
# Add scaling support using randr under x11
patch -p1 -i "${srcdir}/mutter-45.0-x11-Add-support-for-fractional-scaling-using-Randr.patch"
}
build() {
local meson_options=(
-D docs=false
-D egl_device=true
-D installed_tests=false
-D libdisplay_info=true
-D wayland_eglstream=true
)
CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
LDFLAGS+=" -Wl,-Bsymbolic-functions"
arch-meson mutter build "${meson_options[@]}"
meson compile -C build
}
check() (
export XDG_RUNTIME_DIR="$PWD/rdir" GSETTINGS_SCHEMA_DIR="$PWD/build/data"
mkdir -p -m 700 "$XDG_RUNTIME_DIR"
glib-compile-schemas "$GSETTINGS_SCHEMA_DIR"
export NO_AT_BRIDGE=1 GTK_A11Y=none
export MUTTER_DEBUG_DUMMY_MODE_SPECS="800x600@10.0"
xvfb-run -s '-nolisten local +iglx -noreset' \
mutter/src/tests/meta-dbus-runner.py --launch=pipewire --launch=wireplumber \
meson test -C build --print-errorlogs -t 5 --setup plain || :
)
package() {
meson install -C build --destdir "$pkgdir"
}
|