blob: 4aece11694b5cc70d047d1196632d829e8560bcd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
pkgname=muwire-git
pkgver=0.8.12.r0.gf2b2c203
pkgrel=1
pkgdesc='An I2P file sharing program (git version)'
arch=('any')
url='https://muwire.com/'
license=('GPL3')
depends=('sh' 'java-runtime>=11' 'hicolor-icon-theme')
optdepends=('i2p-router: for connecting through a local I2P router')
makedepends=('git' 'gradle')
provides=('muwire')
conflicts=('muwire')
source=('git+https://github.com/zlatinb/muwire.git'
'muwire.desktop'
'muwire.sh')
sha256sums=('SKIP'
'7d61c69613029bd2b2e82f227a230104b880635fd8d44a649b2192b03c3cc509'
'390c11231788eb36601d68c74dc08bf94422792c098926444c688f92a143f599')
pkgver() {
git -C muwire describe --long --tags | sed 's/^\(muwire\|plugin\)-//;s/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
gradle -p muwire clean assemble
}
check() {
local _javamaj
_javamaj="$(javac --version | awk '/javac/ { sub(/\..*/, "", $2); print $2 }')"
[ "$_javamaj" -ge '18' ] && return 0
gradle -p muwire test
}
package() {
local _ver
_ver="$(sed 's/\.[br].*//' <<< "$pkgver")"
bsdtar -xf "muwire/gui/build/distributions/gui-shadow-${_ver}.tar" \
-C muwire --strip-components='2' "*/lib/gui-${_ver}-all.jar"
install -D -m755 muwire.sh "${pkgdir}/usr/bin/muwire"
install -D -m644 muwire.desktop -t "${pkgdir}/usr/share/applications"
install -D -m644 "muwire/gui-${_ver}-all.jar" "${pkgdir}/usr/share/java/muwire.jar"
local _file
local _res
while read -r -d '' _file
do
_res="$(sed 's/\.png$//;s/^.*x//' <<< "$_file")"
install -D -m644 "$_file" "${pkgdir}/usr/share/icons/hicolor/${_res}x${_res}/apps/muwire.png"
done < <(find muwire/gui/griffon-app/resources -maxdepth 1 -type f -name 'MuWire-*x*.png' -print0)
}
|