blob: af9273757d2a0a0ed6ddbf73b4336fa5604b479a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Petko Bordjukov <bordjukov@gmail.com>
_pkgname=mythes-bg
pkgname="$_pkgname"-git
pkgver=r2331.93db4f5
pkgrel=1
pkgdesc="Bulgarian thesaurus"
arch=(any)
url="https://docs.libreoffice.org/lingucomponent.html"
license=('GPL2')
optdepends=('libmythes: offers thesaurus library functions')
makedepends=('perl')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=(dictionaries::git+https://github.com/LibreOffice/dictionaries.git
mythes::git+https://github.com/hunspell/mythes.git)
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd "$srcdir"/dictionaries
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir"/dictionaries/bg_BG
cat th_bg_BG_v2.dat | "$srcdir"/mythes/th_gen_idx.pl > th_bg_BG_v2.idx
}
package() {
cd "$srcdir"
# dictionary
install -dm755 "${pkgdir}"/usr/share/mythes
cp -p dictionaries/bg_BG/th_bg_BG_v2.dat "${pkgdir}"/usr/share/mythes/
cp -p dictionaries/bg_BG/th_bg_BG_v2.idx "${pkgdir}"/usr/share/mythes/
# symlink
install -dm755 "${pkgdir}"/usr/share/myspell/dicts
ln -s /usr/share/mythes/th_bg_BG_v2.dat "${pkgdir}"/usr/share/myspell/dicts/
ln -s /usr/share/mythes/th_bg_BG_v2.idx "${pkgdir}"/usr/share/myspell/dicts/
# license
install -D -m644 "${srcdir}"/dictionaries/bg_BG/COPYING "${pkgdir}"/usr/share/licenses/"$pkgname"/LICENSE
# docs
install -dm755 "$pkgdir"/usr/share/doc/"$pkgname"
cp -p dictionaries/bg_BG/README_th_bg_BG_v2.txt "$pkgdir"/usr/share/doc/"$pkgname"
}
|