blob: 340e279db4f710472a97a0d0c4119c9fa4919d21 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: bgme <i@bgme.me>
# Contributor: navigaid <navigaid@gmail.com>
pkgname=naiveproxy
pkgdesc="A Proxy using Chrome's network stack to camouflage traffic with strong censorship resistence and low detectablility."
pkgver=95.0.4638.54
pkgrel=3
arch=('x86_64')
url='https://github.com/klzgrad/naiveproxy'
license=('BSD')
depends=('nspr' 'nss')
makedepends=("ninja" "python2" "unzip")
optdepends=("ccache: Speed up compilation")
_WITH_CLANG='Linux_x64'
_WITH_PGO='linux'
_WITH_GN='linux'
_clang_path='clang-llvmorg-14-init-3191-g0e03450a-1.tgz'
_PGO_PATH='chrome-linux-4638-1634308623-72bf2d0e0b11b9cb785718016169434ba1d25ee3.profdata'
_gn_version='git_revision:69ec4fca1fa69ddadae13f9e6b7507efa0675263'
_gn_revision='39a87c0b36310bdf06b692c098f199a0d97fc810'
sha256sums=(
"2489bffda3e0a993cf7e4e8dd6bb5d99e5793c49251ee7dad8612214a3badd03"
"c05026423ca08e2c712745b717c23395e344f2c99b2dad30beed8e26922d268f"
"daa0f591233625730168f3ea006f1d5a7e439e26b35a1051d957e394aa8a4440"
"5bc9ef361e6303e151b6e63deb31b47e24a4f34ade4d8f092a04bc98e89a2edb"
"dd7479d43ce61401e057a5dee8b7e32bc2bd0d0e15d4f46c6858daf9170c9978"
"252703067ad0897cc0f39f618eb792b0899769bb0e1b715b64bee15bcfba6f0b"
"8bedd600ac58311f384e5113ab6a544bc72edb587ccb8f9e784c4dff208872c4"
)
source=(
"${pkgname}-${pkgver}-${pkgrel}.tar.gz::https://github.com/klzgrad/naiveproxy/archive/refs/tags/v${pkgver}-${pkgrel}.tar.gz"
"naiveproxy.service"
"naiveproxy@.service"
"naiveproxy.sysusers"
"${_clang_path}::https://commondatastorage.googleapis.com/chromium-browser-clang/${_WITH_CLANG}/${_clang_path}"
"${_PGO_PATH}::https://storage.googleapis.com/chromium-optimization-profiles/pgo_profiles/${_PGO_PATH}"
"gn-${_gn_revision}.zip::https://chrome-infra-packages.appspot.com/dl/gn/gn/${_WITH_GN}-amd64/+/${_gn_version}"
)
noextract=(
"${_clang_path}"
"${_PGO_PATH}"
"gn-${_gn_revision}.zip"
)
backup=(etc/naiveproxy/config.json)
provides=('naiveproxy')
conflicts=('naiveproxy-git' 'naiveproxy-bin')
prepare() {
SRC_DIR="${srcdir}/${pkgname}-${pkgver}-${pkgrel}/src"
mkdir -p ${SRC_DIR}/third_party/llvm-build/Release+Asserts
tar xzf ${_clang_path} -C ${SRC_DIR}/third_party/llvm-build/Release+Asserts
mkdir -p ${SRC_DIR}/chrome/build/pgo_profiles
cp ${_PGO_PATH} ${SRC_DIR}/chrome/build/pgo_profiles
mkdir -p ${SRC_DIR}/gn/out
unzip gn-${_gn_revision}.zip -d ${SRC_DIR}/gn/out
}
build(){
SRC_DIR="${srcdir}/${pkgname}-${pkgver}-${pkgrel}/src"
pushd ${SRC_DIR}
./build.sh
popd
}
package(){
pushd ${srcdir}
install -Dm644 naiveproxy.service ${pkgdir}/usr/lib/systemd/system/naiveproxy.service
install -Dm644 naiveproxy@.service ${pkgdir}/usr/lib/systemd/system/naiveproxy@.service
install -Dm644 naiveproxy.sysusers ${pkgdir}/usr/lib/sysusers.d/naiveproxy.conf
popd
pushd ${srcdir}/${pkgname}-${pkgver}-${pkgrel}
install -d -m750 -o 0 -g 287 ${pkgdir}/etc/naiveproxy
install -Dm644 src/config.json ${pkgdir}/etc/naiveproxy/config.json
install -Dm755 src/out/Release/naive ${pkgdir}/usr/bin/naiveproxy
install -Dm644 README.md ${pkgdir}/usr/share/doc/naiveproxy/README.md
install -Dm644 USAGE.txt ${pkgdir}/usr/share/doc/naiveproxy/USAGE.txt
install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/naiveproxy/LICENSE
popd
}
|