blob: b6bf118305c2ddf45f56fd47d547b28c06eebf04 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Zosoled <zosoled@codecow.xyz>
pkgname=nano-vanity-git
_pkgname=${pkgname%-git}
_author=PlasmaPower
pkgver=r88.caa7274
pkgrel=3
pkgdesc='Vanity address generator for nano cryptocurrency.'
arch=(x86_64)
url=https://github.com/${_author}/${_pkgname}
license=(BSD-2-Clause)
provides=(${_pkgname}=${pkgver})
conflicts=(${_pkgname})
depends=(
glibc
gcc-libs
ocl-icd
)
makedepends=(
git
rust
)
optdepends=(
'cuda: NVIDIA GPU support'
'rocm-opencl-runtime: AMD GPU support for GFX8 and later cards'
)
source=(
${_pkgname}-${pkgver}::git+${url}.git
LICENSE::https://raw.githubusercontent.com/${_author}/${_pkgname}/master/LICENSE
)
sha512sums=(
'SKIP'
'd4e9f56bec22cc7a82f107378defbe500a2adc49489842182e7ab2344953c14da77de5003e275e9978f99af44938bb8524d4a514ed91cf04f1b1dc88086f2b05'
)
pkgver() {
cd "${srcdir}"/${_pkgname}-${pkgver}
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "${srcdir}"/${_pkgname}-${pkgver}
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${srcdir}"/${_pkgname}-${pkgver}
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "${srcdir}"/${_pkgname}-${pkgver}
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd "${srcdir}"/${_pkgname}-${pkgver}
install -Dm0755 -t "${pkgdir}"/usr/bin target/release/${_pkgname}
install -Dm0644 -t "${pkgdir}"/usr/share/licenses/${_pkgname} LICENSE
}
|